on *:Start:{
  if (!$hget(Visits)) {
    hmake Visits
  }
  if ($exists(Visits.txt)) {
    hload Visits Visits.txt
  }
}

on *:Exit:{
  hsave Visits Visits.txt
}

on *:Join:#:{
  var %x = $calc($gettok($hget(Visits,$+($network,.,Count,.,$chan)),1,32) + 1)
  var %y = $calc($gettok($hget(Visits,$+($network,.,$chan,.,$nick)),1,32) + 1)
  if (!$hget(Visits,$+($network,.,Count,.,$chan))) {
    notice $nick Welcome to $+($chan,$chr(44)) $+($nick,.) You are the $ord(1) person to join $+($chan,.)
    hadd Visits $+($network,.,Count,.,$chan) 1
    hadd Visits $+($network,.,$chan,.,$nick) 1 $asctime(mm/dd/yyyy) $ctime
  }
  elseif (!$hget(Visits,$+($network,.,$chan,.,$nick))) {
    notice $nick Welcome to $+($chan,$chr(44)) $+($nick,.) You are the $ord(%x) person to join $+($chan,.)
    hadd Visits $+($network,.,$chan,.,$nick) 1 $asctime(mm/dd/yyyy) $ctime
    hadd Visits $+($network,.,Count,.,$chan) %x
  }
  else {
    notice $nick Welcome to $+($chan,$chr(44)) $+($nick,.) This is your $ord(%y) visit to $+($chan,.) Your last visit was on $+($gettok($hget(Visits,$+($network,.,$chan,.,$nick)),2,32),$chr(44)) $duration($calc($ctime - $gettok($hget(Visits,$+($network,.,$chan,.,$nick)),3,32))) ago.
    hadd Visits $+($network,.,$chan,.,$nick) %y $asctime(mm/dd/yyyy) $ctime
  }
}

on $*:Text:/^[!@]Visitors/Si:#:{
  var %target $iif($left($1,1) == @,msg $chan,notice $nick)
  if (!$2) {
    if (!$hget(Visits,$+($network,.,Count,.,$chan))) {
      %target I have not recorded anyone joining $+($chan,.)
    }
    elseif ($gettok($hget(Visits,$+($network,.,Count,.,$chan)),1,32) = 1) {
      %target $chan has had 1 visitor.
    }
    else {
      %target $chan has had $bytes($gettok($hget(Visits,$+($network,.,Count,.,$chan)),1,32),b) visitors.
    }
  }
  if ($2) {
    $iif($left($2,1) == $chr(35),set %a $2,set %a $+($chr(35),$2))
    if (!$hget(Visits,$+($network,.,Count,.,%a))) {
      %target I have not recorded anyone joining $+(%a,.)
    }
    else {
      if ($gettok($hget(Visits,$+($network,.,Count,.,%a)),1,32) = 1) {
        %target %a has had 1 visitor.
      }     
      else {
        %target %a has had $bytes($gettok($hget(Visits,$+($network,.,Count,.,%a)),1,32),b) visitors.
      }
    }     
    unset %a
  }       
}

on $*:Text:/^[!@]Visits/Si:#:{
  var %target $iif($left($1,1) == @,msg $chan,notice $nick)
  if (!$2) {
    if (!$hget(Visits,$+($network,.,$chan,.,$nick))) {
      %target I have not recorded $nick joining $+($chan,.)
    }
    elseif ($gettok($hget(Visits,$+($network,.,$chan,.,$nick)),1,32) == 1) {
      %target $nick has visited $chan 1 time, your last visit was on $+($gettok($hget(Visits,$+($network,.,$chan,.,$nick)),2,32),$chr(44)) $duration($calc($ctime - $gettok($hget(Visits,$+($network,.,$chan,.,$nick)),3,32))) ago.
    }
    else {
      %target $nick has visited $chan $bytes($gettok($hget(Visits,$+($network,.,$chan,.,$nick)),1,32),b) times, your last visit was on $+($gettok($hget(Visits,$+($network,.,$chan,.,$nick)),2,32),$chr(44)) $duration($calc($ctime - $gettok($hget(Visits,$+($network,.,$chan,.,$nick)),3,32))) ago.
    }
  }
  if ($2) {
    if (!$3) {
      if (!$hget(Visits,$+($network,.,$chan,.,$2))) {
        %target I have not recorded $2 joining $+($chan,.)
      }
      elseif ($gettok($hget(Visits,$+($network,.,$chan,.,$2)),1,32) == 1) {
        %target $2 has visited $chan 1 time, their last visit was on $+($gettok($hget(Visits,$+($network,.,$chan,.,$2)),2,32),$chr(44)) $duration($calc($ctime - $gettok($hget(Visits,$+($network,.,$chan,.,$2)),3,32))) ago.
      }
      else {
        %target $2 has visited $chan $bytes($gettok($hget(Visits,$+($network,.,$chan,.,$2)),1,32),b) times, their last visit was on $+($gettok($hget(Visits,$+($network,.,$chan,.,$2)),2,32),$chr(44)) $duration($calc($ctime - $gettok($hget(Visits,$+($network,.,$chan,.,$2)),3,32))) ago.
      }
    }
    else {
      $iif($left($3,1) == $chr(35),set %b $3,set %b $+($chr(35),$3))
      if (!$hget(Visits,$+($network,.,%b,.,$2))) {
        %target I have not recorded $2 joining $+(%b,.)
      }
      elseif ($gettok($hget(Visits,$+($network,.,%b,.,$2)),1,32) == 1) {
        %target $2 has visited %b 1 time, their last visit was on $+($gettok($hget(Visits,$+($network,.,%b,.,$2)),2,32),$chr(44)) $duration($calc($ctime - $gettok($hget(Visits,$+($network,.,%b,.,$2)),3,32))) ago.
      }
      else {
        %target $2 has visited %b $bytes($gettok($hget(Visits,$+($network,.,%b,.,$2)),1,32),b) times, their last visit was on $+($gettok($hget(Visits,$+($network,.,%b,.,$2)),2,32),$chr(44)) $duration($calc($ctime - $gettok($hget(Visits,$+($network,.,%b,.,$2)),3,32))) ago.
      }
      unset %b   
    }     
  }
}