[script]
n0=alias c1 { return $+($chr(3),14, ,$chr(2),$1-) } 
n1=alias c2 { return $+($chr(3),07, ,$chr(2),$1-) } 
n2=
n3=on *:text:*:#: { 
n4=  tokenize 32 $strip($1-) 
n5=  if ($left($1,1) !isin @!.) halt 
n6=  if ($right($1,-1) == stats) var %style = astats 
n7=  elseif ($regex($1,/co?mb(at)?/Si)) var %style = combat 
n8=  elseif ($setskill($remove($1,@,!,.))) var %style = istat, %skill = $setskill($remove($1,@,!,.)) 
n9=  elseif ($right($1,-1) == setrsn) && ($2) { 
n10=    if ($2 == -h) { 
n11=      writeini DefRSN.ini RSNs $mask($fulladdress,3) $replace($3-,$chr(32),-) 
n12=      .notice $nick You're default RSN for the host $mask($fulladdress,3) has been set to $3- 
n13=    } 
n14=    else { 
n15=      writeini DefRSN.ini RSNs $nick $replace($2-,$chr(32),-) 
n16=      .notice $nick You're default RSN for the nick $nick has been set to $2- 
n17=    } 
n18=    halt 
n19=  } 
n20=  else halt 
n21=
n22=  inc %ID 
n23=  if ($len($2-) > 12) { 
n24=    $($+(%,stats.display.,%ID),2) $c1(The nick) $c2($2-) $c1(is too long) 
n25=    cleanup %ID 
n26=    halt 
n27=  } 
n28=  elseif ($2) set $+(%,stats.rsn.,%ID) $replace($2-,$chr(32),-) 
n29=  elseif ($readini(DefRSN.ini,RSNs,$mask($fulladdress,3))) set $+(%,stats.rsn.,%ID) $ifmatch 
n30=  elseif ($readini(DefRSN.ini,RSNs,$nick)) set $+(%,stats.rsn.,%ID) $ifmatch 
n31=  else set $+(%,stats.rsn.,%ID) $nick 
n32=
n33=  set $+(%,stats.style.,%ID) %style 
n34=  set $+(%,stats.skill.,%ID) %skill 
n35=  set $+(%,stats.display.,%ID) $iif($left($1,1) == @,msg $chan,notice $nick) 
n36=  sockopen $+(stats.,%ID) hiscore.runescape.com 80 
n37=} 
n38=
n39=on *:sockopen:stats.*: { 
n40=  var %id = $gettok($sockname,2,46) 
n41=  sockwrite -n $sockname GET /lang/en/aff/runescape/hiscorepersonal.ws?user1= $+ $($+(%,stats.rsn.,%ID),2) HTTP/1.1 
n42=  sockwrite -n $sockname Host: hiscore.runescape.com $+ $crlf $+ $crlf 
n43=} 
n44=on *:sockread:stats.*: { 
n45=  sockread &Incoming 
n46=  bwrite $sockname -1 -1 &Incoming 
n47=  if ($bfind(&Incoming, 1, </html>).text) makehash $sockname 
n48=  elseif ($bfind(&Incoming, 1, does not feature in the hiscores.).text) { 
n49=    $($+(%,stats.display.,%ID),2) $c1(The nick) $c2($($+(%,stats.rsn.,%ID),2)) $c1(Does not appear in the hiscores) 
n50=    cleanup $gettok($sockname,2,46) 
n51=  } 
n52=} 
n53=alias -l makehash { 
n54=  var %file = $1 
n55=  bread %file 1 $file(%file).size &stats 
n56=  var %currentstat, %x = 1 
n57=  while (%x) { 
n58=    var %x = $bfind(&stats,$calc(%x + 1),<a href="overall.ws?table=) 
n59=    var %currentstat = $striptags($bvar(&stats,%x,200).text) 
n60=    tokenize 32 %currentstat 
n61=    hadd -m %file $1 $2 $3 $4 $xp2next($3,$4) 
n62=  } 
n63=  process %file 
n64=} 
n65=alias process { 
n66=  var %table = $1, %id = $gettok($1,2,46), %x = 0, $& 
n67=    %display = $($+(%,stats.display.,%ID),2), $& 
n68=    %rsn = $($+(%,stats.rsn.,%ID),2), $& 
n69=    %skill = $($+(%,stats.skill.,%ID),2), $& 
n70=    %style = $($+(%,stats.style.,%ID),2) 
n71=
n72=  if (%style == astats) { 
n73=    while (%x <= 22) { 
n74=      tokenize 32 $hget(%table,$setskill(%x)) 
n75=      if ($2) var %statline = %statline $c1($setskill(%x)) $c2($2) 
n76=      inc %x 
n77=    } 
n78=    %display $c1(Stats for) $c2(%rsn) $+ $c1(:) 
n79=    %display %statline 
n80=  } 
n81=  elseif (%style == istat) { 
n82=    if (!$hget(%table,%skill)) %display $c1(The nick) $c2(%rsn) $c1(does not appear in the hiscores for) $c2(%skill) 
n83=    else { 
n84=      tokenize 32 $hget(%table,%skill) 
n85=      %display $c2(%skill) $c1(stats for) $c2(%rsn) $+ $c1(:) 
n86=      %display $c1(Rank:) $c2($1) $c1(Level:) $c2($bytes($2,b)) $c1(Exp:) $c2($3) $& 
n87=        $iif(%skill != Overall,$c1(Exp to lvl) $c2($calc($2 + 1)) $+ $c1(:) $c2($bytes($4,b))) 
n88=    } 
n89=  } 
n90=  elseif (%style == combat) { 
n91=    var %a.mult = .32707, %s.mult = .324, %d.mult = .25, %h.mult = .25, %p.mult = .124, %r.mult = .487, %m.mult = .487 
n92=    var %a = $iif($gettok($hget(%table,attack),2,32),$v1,-), $& 
n93=      %s = $iif($gettok($hget(%table,strength),2,32),$v1,-), $& 
n94=      %d = $iif($gettok($hget(%table,defence),2,32),$v1,-), $& 
n95=      %h = $iif($gettok($hget(%table,hitpoints),2,32),$v1,-), $& 
n96=      %r = $iif($gettok($hget(%table,ranged),2,32),$v1,-), $& 
n97=      %m = $iif($gettok($hget(%table,magic),2,32),$v1,-), $& 
n98=      %p = $iif($gettok($hget(%table,prayer),2,32),$v1,-) 
n99=
n100=    var %meleecombat  = $calc(%a * %a.mult + %s * %s.mult + %d * %d.mult + %h * %h.mult + %p * %p.mult), $& 
n101=      %RangedCombat = $calc(%r * %r.mult + %p * %p.mult + %d * %d.mult + %h * %h.mult), $& 
n102=      %MagicCombat  = $calc(%m * %m.mult + %p * %p.mult + %d * %d.mult + %h * %h.mult) 
n103=
n104=    if (%MagicCombat == %RangedCombat) && (%MagicCombat == %RangedCombat) { 
n105=      %display $c1(The nick) $c2(%rsn) $c1(does not appear in the hiscores for any combat skills) 
n106=      cleanup %id 
n107=      halt 
n108=    } 
n109=    elseif (%MagicCombat > %RangedCombat) && (%MagicCombat > %MeleeCombat) var %cmbstyle = Magic, %Combat = %MagicCombat 
n110=    elseif (%RangedCombat > %MeleeCombat) var %cmbstyle = Ranged, %Combat = %RangedCombat 
n111=    else var %cmbstyle = melee, %combat = %MeleeCombat 
n112=
n113=    var %cmb.temp = $abs($calc($int($calc(%combat +1)) - %combat)), $& 
n114=      %a.2lvl = $ceil($calc(%cmb.temp / %a.mult)), %s.2lvl = $ceil($calc(%cmb.temp / %s.mult)), $& 
n115=      %d.2lvl = $ceil($calc(%cmb.temp / %d.mult)), %m.2lvl = $ceil($calc(%cmb.temp / %m.mult)), $& 
n116=      %r.2lvl = $ceil($calc(%cmb.temp / %r.mult)), %p.2lvl = $ceil($calc(%cmb.temp / %p.mult)) 
n117=
n118=    if (%cmbstyle == magic) var %dynamic.2lvl = $c1(Magic:) $c2(%m.2lvl) 
n119=    elseif (%cmbstyle == Ranged) var %dynamic.2lvl = $c1(Ranged:) $c2(%r.2lvl) 
n120=    else var %dynamic.2lvl = $c1(Att:) $c2(%a.2lvl) $c1(Str:) $c2(%s.2lvl) 
n121=    var %combat = $round(%combat,2), %next = $ceil(%combat) 
n122=
n123=    %display $c2(%rsn) $c1(is) $c2(%combat) $c1(%cmbstyle style combat) 
n124=    %display $c1(Attack:) $c2(%a) $c1(Defence:) $c2(%d) $c1(Strength:) $c2(%s) $c1(Hits:) $c2(%h) $& 
n125=      $c1(Mage:) $c2(%m) $c1(Range:) $c2(%r) $c1(Pray:) $c2(%p) 
n126=    %display $c1(Levels for) $c2(%next) $+ $c1(:) %dynamic.2lvl $& 
n127=      $c1(Def/Hp:) $c2(%d.2lvl) $c1(Prayer:) $c2(%p.2lvl) 
n128=  } 
n129=  cleanup %id 
n130=} 
n131=
n132=alias -l cleanup { 
n133=  unset $+(%,stats.*.,$1) 
n134=  sockclose $+(Stats.,$1) 
n135=  .remove $+(Stats.,$1) 
n136=} 
n137=
n138=alias -l xp { 
n139=  var %x = 1, %level = $calc($1 - 1), %xp = 0 
n140=  while (%x <= %level) { 
n141=    var %TempXp = $calc((%x + 300 * 2^(%x / 7)) /4) 
n142=    inc %xp %TempXp 
n143=    inc %x 
n144=  } 
n145=  return $int(%xp) 
n146=} 
n147=
n148=alias -l xp2Next { 
n149=  var %xp = $remove($2,$chr(44)), %nextxp = $xp($calc($1 + 1)) 
n150=  return $calc(%nextxp - %xp) 
n151=} 
n152=
n153=alias -l striptags { var %x,%y = $regsub($1-,/(<[^>]+>)/g,$null,%x) | return %x } 
n154=alias -l setskill { 
n155=  if ($1 == 0) || ($regex($1,/^(st|(skill)?total|overall)$/Si)) return Overall 
n156=  elseif ($1 == 1) || ($regex($1,/^at(t|k|tack)$/Si)) return Attack 
n157=  elseif ($1 == 2) || ($regex($1,/^def(en[cs]e)?$$/Si)) return Defence 
n158=  elseif ($1 == 3) || ($regex($1,/^str(ength)?$/Si)) return Strength 
n159=  elseif ($1 == 4) || ($regex($1,/^hp|hit(s|points?)?$/Si)) return Hitpoints 
n160=  elseif ($1 == 5) || ($regex($1,/^range(r|d|ing)?$/Si)) return Ranged 
n161=  elseif ($1 == 6) || ($regex($1,/^Pray(er)?$$/Si)) return Prayer 
n162=  elseif ($1 == 7) || ($regex($1,/^mag(e|ic)$$/Si)) return Magic 
n163=  elseif ($1 == 8) || ($regex($1,/^cook(ing)?$/Si)) return Cooking 
n164=  elseif ($1 == 9) || ($regex($1,/^wc|wood(cut(ting)?)?$/Si)) return Woodcutting 
n165=  elseif ($1 == 10) || ($regex($1,/^fletch(ing)?$/Si)) return Fletching 
n166=  elseif ($1 == 11) || ($regex($1,/^fish(ing)?$/Si)) return Fishing 
n167=  elseif ($1 == 12) || ($regex($1,/^(fire|fm)(make?(ing)?|ing)?$/Si)) return Firemaking 
n168=  elseif ($1 == 13) || ($regex($1,/^craft(ing)?$/Si)) return Crafting 
n169=  elseif ($1 == 14) || ($regex($1,/^(smith|smelt)(ing)?$/Si)) return Smithing 
n170=  elseif ($1 == 15) || ($regex($1,/^mine(ing)?$/Si)) return Mining 
n171=  elseif ($1 == 16) || ($regex($1,/^herb(law|lore)?$/Si)) return Herblore 
n172=  elseif ($1 == 17) || ($regex($1,/^agil(ity)?$/Si)) return Agility 
n173=  elseif ($1 == 18) || ($regex($1,/^(th(ei|ie)[fv](e|ing)?)$/Si)) return Thieving 
n174=  elseif ($1 == 19) || ($regex($1,/^slay(er|ing)?$/Si)) return Slayer 
n175=  elseif ($1 == 20) || ($regex($1,/^farm(er|ing)?$/Si)) return Farming 
n176=  elseif ($1 == 21) || ($regex($1,/^(rc|runecraft)(er|ing)?$/Si)) return Runecraft 
n177=  elseif ($1 == 22) || ($regex($1,/^(cons|construction)?$/Si)) return Construction 
n178=}