# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: media-sound/amarok-svn/amarok-svn-1.4.ebuild $

inherit kde subversion eutils flag-o-matic

ESVN_REPO_URI="svn://anonsvn.kde.org/home/kde/trunk/extragear/multimedia/amarok"
ESVN_STORE_DIR="${PORTAGE_ACTUAL_DISTDIR-${DISTDIR}}/svn-src/"
SRC_URI="http://shadowfax.homelinux.net/~guru/moodbar/amarokonly-patch.gz"

DESCRIPTION="Advanced audio player based on KDE framework (new moodbar version)."
HOMEPAGE="http://shadowfax.homelinux.net/~guru/moodbar/"

LICENSE="GPL-2"

SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd"
IUSE="aac kde mysql noamazon opengl postgres
xmms visualization ipod ifp real njb"
# kde: enables compilation of the konqueror sidebar plugin

DEPEND="kde? ( || ( kde-base/konqueror kde-base/kdebase ) )
	>=media-libs/xine-lib-1.1.2_pre20060328-r8
	>=media-libs/taglib-1.4
	mysql? ( >=dev-db/mysql-4.0.16 )
	postgres? ( dev-db/postgresql )
	opengl? ( virtual/opengl )
	xmms? ( >=media-sound/xmms-1.2 )
	visualization? ( media-libs/libsdl
					 =media-plugins/libvisual-plugins-0.4* )
	ipod? ( media-libs/libgpod )
	aac? ( media-libs/libmp4v2 )
	ifp? ( media-libs/libifp )
	real? ( media-video/realplayer )
	njb? ( >=media-libs/libnjb-2.2.4 )"

RDEPEND="${DEPEND}
	>=media-sound/moodbar-0.0
	dev-lang/ruby
	!media-sound/amarok"

DEPEND="${DEPEND}
	>=dev-util/pkgconfig-0.9.0
	app-arch/gzip"

need-kde 3.3

src_unpack() {
	ESVN_UPDATE_CMD="svn update -N"
	ESVN_FETCH_CMD="svn checkout -N"
	ESVN_REPO_URI=`dirname "${ESVN_REPO_URI}"`
	subversion_src_unpack

	S="${WORKDIR}/${P}/admin"
	ESVN_REPO_URI="svn://anonsvn.kde.org/home/kde/branches/KDE/3.5/kde-common/admin"
	subversion_src_unpack
	
	ESVN_UPDATE_CMD="svn up -r${PV}"
	ESVN_FETCH_CMD="svn checkout -r${PV}"
	S="${WORKDIR}/${P}/amarok"
	ESVN_REPO_URI="svn://anonsvn.kde.org/home/kde/trunk/extragear/multimedia/amarok"
	subversion_src_unpack

	S="${WORKDIR}/${P}"
	cd ${S}

	einfo "Applying moodbar patch"
	EPATCH_OPTS="-N" # Ignore the patch if the source was already checked out and patched
	gzcat ${DISTDIR}/amarokonly-patch.gz > ${WORKDIR}/amarokonly.patch
	epatch ${WORKDIR}/amarokonly.patch
}

src_compile() {
	export WANT_AUTOMAKE="1.9" # Force usage of automake 1.9 for safety
	append-flags -fno-inline

	# Extra, unsupported engines are forcefully disabled.
	local myconf="$(use_enable mysql) $(use_enable postgres postgresql)
				  $(use_with opengl) $(use_with xmms)
				  $(use_with visualization libvisual)
				  $(use_enable !noamazon amazon)
				  $(use_with ipod libgpod)
				  $(use_with aac mp4v2)
				  $(use_with ifp)
				  $(use_with real helix)
				  $(use_with njb libnjb)
				  --without-musicbrainz
				  --with-xine
				  --without-mas
				  --without-nmm"

	kde_src_compile
}