on *:text:*:#kiffen:{
  var %st = $strip($1-,bcu)
  var %sg = Allgemein Wissen, Sprichwort, Tiere, Fernsehen, Geschichte, Geografie, Sport, Promis, Pflanzen, Anatomie, EDV, Kinder, Lebensmittel, Religion
  if ($regex(st,%st,» (.+?) ::: (.+) «)) {
    if ($regml(st,1) == Nummer) {
      set %st.str
      ; Nummer der aktuellen Frage (init)
    }
    if ($matchtok(%sg,$regml(st,1),0,44)) {
      set %st.str $regml(st,2) $+ $chr(155)
      ; Frage
    }
    if ($regex(sa,$regml(st,1),N° \d+ konnte nicht gelöst werden!) && %st.str) {
      set %st.str %st.str $+ $regml(st,2)
      qt.file -w %st.str
      ; Antwort - Art1
    }
    if ($regex(sa,$regml(st,1),(.+) wusste\W dass wir (.+) suchten!) && %st.str) {
      set %st.str %st.str $+ $regml(sa,2)
      qt.file -w %st.str
      ; Antwort - Art2
    }
  }
  elseif ($regex(st,%st,» (.+) ist richtig (?:.+)! Oh was sehe ich\?(?:.*) ist Dir .+ «)) {
    set %st.str %st.str $+ $regml(st,1)
    qt.file -w %st.str
    ; Antwort - Art3
  }
  elseif ($regex(st,%st,» (.+) wussten (.+) nicht! Nächste Frage:-\W «)) {
    set %st.str %st.str $+ $regml(st,1)
    qt.file -w %st.str
    ; Antwort - Art4
  }
}

alias qt.file {
  if ($$1 == -w) {
    if ($hget(qtfile)) { hfree qtfile }
    hmake qtfile
    if ($exists($+($mircdir,qtfile.txt))) { hload qtfile $+($mircdir,qtfile.txt) }
    if ($hfind(qtfile,$$2-,0).data) { return }
    if (!$hget(qtfile,index)) { hadd qtfile index 1 }
    hadd qtfile $+(q,$hget(qtfile,index)) $2-
    hinc qtfile index
    hsave -o qtfile $+($mircdir,qtfile.txt)
    hfree qtfile
    echo -s $timestamp ›› Wrote q/a $+($chr(40),$gettok($2-,1,155),$chr(47),$gettok($2-,2,155),$chr(41)) to qtfile.
  }
  elseif ($1 == -r) {
    if (!$hget(qtfile)) { hmake qtfile }
    if (!$hget(qtfile,index) && $exists($+($mircdir,qtfile.txt))) { hload qtfile $+($mircdir,qtfile.txt) }
    if ($hfind(qtfile,$$2-*,0,w).data) { return $hget(qtfile,$hfind(qtfile,$$2-*,1,w).data) }
  }
}