alias songpath {
  return $remove($dde(mPlug,var_fn),$dde(mPlug,var_nm))
}

alias song {
  if ($isid) {
    if ($1 = artist) return $dde(mPlug,var_1)
    if ($1 = title) return $dde(mPlug,var_2)
    if ($1 = tracknumber) return $left($dde(mPlug,var_nm),2)
    if ($1 = album) return $dde(mPlug,var_4)
    if ($1 = date) return $dde(mPlug,var_5)
    if ($1 = genre) return $dde(mPlug,var_7)
    if ($1 = length) return $+($dde(mPlug,var_min),:,$dde(mPlug,var_sec))
    if ($1 = current) return $+($dde(mPlug,var_pm),:,$dde(mPlug,var_ps))
    if ($1 = bitrate) return $dde(mPlug,var_br)
    if ($1 = size) return $dde(mPlug,var_fl)
    if ($1 = filename) return $dde(mPlug,var_nm)
    if ($1 = percent) return $dde(mPlug,var_prc)
    if ($1 = playstate) return $dde(mPlug,var_tstat)
    if ($1 = disc) && ($len($dde(mPlug,var_fdir)) == 3) && ($mid($dde(mPlug,var_fdir),3,1) isnum) return $mid($dde(mPlug,var_fdir),3,1)
    if ($1 = position) return $dde(mPlug,var_pos)
    if ($1 = totalsongs) return $dde(mPlug,var_ll)
    if ($1 = various) && (VA - isincs $songpath) return 1
    if ($1 = extension) return $dde(mPlug,var_ext)
    if ($1 = samplerate) return $dde(mPlug,var_sr)
  }
}

alias sn {
  if ($network == Digital-Toxicity) { 
    goto spam 
  }
  else {
    var %confirm $input(Song spam in $active $+ ?,y,Synamp)
    if (%confirm == $true) {
      goto spam
    }
    else {
      halt 
    }
  }
  :spam
  if ($song(title)) {
    if (!$1) {
      if ($song(album)) {
        var %album $+($chr(91),$iif($song(various),$+($chr(40),VA,$chr(41)) $+ $chr(32),$null),$song(album),$chr(32),$iif($song(disc),CD $+ $ifmatch,$null),$chr(32),$chr(35),$song(tracknumber),$chr(93)),$song(album),$chr(32),$chr(35),$song(tracknumber),$chr(93))
      }
      else {
        var %album $null
      }
      var %state $iif($song(playstate) == paused,07*paused*,$null)
      return is listening to $song(artist) - %album $song(title) $+($chr(91),$song(length),/,$song(bitrate),kbps,$chr(93)) %state
    }
    elseif ($1 == min) {
      return np: $song(artist) - $song(title) [ $+ $song(bitrate) $+ kbps]
    }
  }
  else {
    return doesn't have Winamp open
  }
}

alias F12 {
  describe # $sn
}

alias songs {
  if ($isid) && ($1-) {
    var %songs $calc($findfile(d:\music\ $+ $1- $+ ,*.mp3,0) + $findfile(d:\music\ $+ $1- $+ ,*.m4a,0) + $findfile(d:\music\ $+ $1- $+ ,*.flac,0) + $findfile(d:\music\ $+ $1- $+ ,*.ape,0) + $findfile(d:\music\ $+ $1- $+ ,*.ogg,0))
    return %songs
  }
  elseif (!$isid) {
    var %songs $calc($findfile(d:\music\,*.mp3,0) + $findfile(d:\music\,*.m4a,0) + $findfile(d:\music\,*.flac,0) + $findfile(d:\music\,*.ape,0) + $findfile(d:\music\,*.ogg,0))
    var %albms $calc($finddir(d:\music,*,0,2) - $calc($finddir(d:\music,*,0,1)-1))
    describe # has $+(,%songs,) songs on $+(,%albms,) albums ( $+ $foldersize(d:\music,g) $+ GB $+ )
  }
}

alias delyear {
  return $remove($$1-,$left($$1-,7))
}

alias albums {
  var %path d:\music\ $+ $1 $+ \
  if ($isid) {
    if $isdir(%path) && (!$2) {
      return $finddir(%path,*,0)
    }
    elseif ($2) && ($2 isnum) {
      var %album $finddir(%path,*,$2)
      if ($exists($+(%album,\,folder.jpg))) {
        var %coverart 1
        if ($exists($+(%album,\,Thumbs.db))) {
          var %tracks $calc($findfile(%album,*,0) - 2)
        }
        elseif (!$exists($+(%album,\,Thumbs.db))) {
          var %tracks $calc($findfile(%album,*,0) - 1)
        }
      } 
      elseif (!$exists($+(%album,\,folder.jpg))) {
        var %tracks $findfile(%album,*,0)
      }
      var %cover $iif(%coverart == 1,has cover art,no cover art)
      var %temp $deltok(%album,1-3,92)
      var %albumname $delyear(%temp)
      var %year $gettok($gettok(%temp,1,41),1,40)
      return %albumname $+($chr(40),%year,$chr(59),$chr(32),%tracks tracks,$chr(59),$chr(32),%cover,$chr(41))
    }
  }
}