DESCRIPTION = "LCDproc is a client/Server suite to drive all kinds of LCD (-like) devices. The client \
shipped with this package can be used to acquire various kinds of system stats. This version is compiled with USB support"
HOMEPAGE = "http://lcdproc.org"
LICENSE = "GPL"
PRIORITY = "optional"
MAINTAINER = "Oyvind Repvik <nail@nslu2-linux.org>"
SECTION = "utils"
PR="r1"

DEPENDS = "libusb"
RRECOMMENDS_lcdproc = "lcdd-usb"

SRC_URI = "${SOURCEFORGE_MIRROR}/lcdproc/lcdproc-${PV}.tar.gz"

S = "${WORKDIR}/lcdproc-${PV}"

inherit autotools update-rc.d

PACKAGES =+ "lcdd-usb lcdd-usb-driver-cfontz \
		lcdd-usb-driver-hd44780  \
        lcdd-usb-driver-text \
		lcdd-usb-driver-iowarrior"

CONFFILES_lcdd-usb = "${sysconfdir}/LCDd.conf"
CONFFILES_lcdproc-usb = "${sysconfdir}/lcdproc.conf"

FILES_lcdd-usb = "${CONFFILES_lcdd-usb} \
	${sbindir}/LCDd \
	${sysconfdir}/init.d/lcdd"

FILES_lcdproc-usb = "${CONFFILES_lcdproc-usb} \
	${bindir}/lcdproc \
	${sysconfdir}/init.d/lcdproc"

# Driver packages

FILES_lcdd-usb-driver-cfontz 	= "${libdir}/lcdproc/CFontzPacket.so"
FILES_lcdd-usb-driver-hd44780 	= "${libdir}/lcdproc/hd44780.so"
FILES_lcdd-usb-driver-text 		= "${libdir}/lcdproc/text.so"
FILES_lcdd-usb-driver-iowarrior	= "${libdir}/lcdproc/IOWarrior.so"

INITSCRIPT_PACKAGES = "lcdd-usb lcdproc-usb"
INITSCRIPT_NAME_lcdd-usb = "lcdd"
INITSCRIPT_NAME_lcdproc-usb = "lcdproc"
INITSCRIPT_PARAMS_lcdd-usb = "defaults 70 21"
INITSCRIPT_PARAMS_lcdproc-usb = "defaults 71 20"

EXTRA_OECONF = "--enable-drivers=CFontzPacket,hd44780,IOWarrior,text --enable-libusb"

do_install () {
	# binaries
	install -D -m 0755 server/LCDd ${D}${sbindir}/LCDd
	install -D -m 0755 clients/lcdproc/lcdproc ${D}${bindir}/lcdproc

	# init scripts
	install -d ${D}${sysconfdir}/init.d
	# so far, not fixed :-( and now even uglier :-((
	cat scripts/init-LCDd.debian | sed -e s'/--oknodo//' -e 's/ -s -f / -s 1 -f 1 /' -e 's/force-reload/force-restart/' -e 's/sleep 1/sleep 4/' > ${D}${sysconfdir}/init.d/lcdd
	chmod 0755 ${D}${sysconfdir}/init.d/lcdd
	# prevent lcdproc from starting if no SCREENS are set.
	# will be fixed in next upstream release
	cat scripts/init-lcdproc.debian | sed -e 's/C X//' | sed -e 's/case/[ -n "$SCREENS" ] || exit 0\n\ncase/' | sed -e s'/--oknodo//' > ${D}${sysconfdir}/init.d/lcdproc
	chmod 0755 ${D}${sysconfdir}/init.d/lcdproc

	# configuration files
	install -D -m 0644 LCDd.conf ${D}${sysconfdir}/LCDd.conf
	# don't start lcdproc by default
	# will be fixed in next upstream release
	cat scripts/lcdproc.conf | sed -e 's/C X//' > ${D}${sysconfdir}/lcdproc.conf
	chmod 0644 ${D}${sysconfdir}/lcdproc.conf

	# driver library files
	install -d ${D}${libdir}/lcdproc
	for i in server/drivers/*.so; do
    	install -m 0644 $i ${D}${libdir}/lcdproc/
	done
}