on $*:text:/^[!@]price(s|check)*/Si:#: { 
  if ( !$2 ) { notice $nick Please type in something to search for Ex. !price <item> } 
  else { 
    /var %number 1 
    while ($sock(price.socket. $+ %number)) { /inc %number } 
    if (!* iswm $1) { /set %price.displaystyle. [ $+ [ %number ] ] private } 
    /set %price.item. [ $+ [ %number ] ] $2- 
    /set %price.nick. [ $+ [ %number ] ] $nick 
    /set %price.chan. [ $+ [ %number ] ] $chan 
    /sockopen $+(price.socket.,%number) zybez.net 80 
  } ;Closes Else 
} ;Ends the !pricecheck section 

on *:sockopen:price.socket.*:{ 
  sockwrite -nt $sockname GET /priceguide.php?search_terms= $+ $replace(%price.item. [ $+ [ $right($SockName,-13) ] ] ,$chr(32),$chr(43)) $+ &search_area=1&price_low=&price_high=&member=1 HTTP/1.1 
  sockwrite -nt $sockname Host: zybez.net 
  sockwrite -nt $sockname $crlf $crlf 
} 

on *:sockread:price.socket.*:{ 
  var %i $right($sockname,-13) 
  if ($sockerr) { /notice %price.nick. [ $+ [ %i ] ] Sorry but an error occured while searching for %price.item. [ $+ [ %i ] ] | halt } 
  else { 
    var %temptext 
    sockread %temptext 

    if (%readnextline == 2) { 
      /inc %price.displayed. [ $+ [ %i ] ] 
      /var %price.displayprice $htmlfree(%temptext) 
      /var %message %price.displayitem. [ $+ [ %i ] ] - %price.displayprice 
      /unset %readnextline 

      if ( %price.displayed. [ $+ [ %i ] ] < 6 ) { 
        if ( %price.displaystyle. [ $+ [ %i ] ] == private ) { /notice %price.nick. [ $+ [ %i ] ] 7[1Price7]:4 %message   } 
        else { /msg %price.chan.  [ $+ [ %i ] ] 7[1Price7]:4 %message  } 
      }  
      else { /notice %price.nick. [ $+ [ %i ] ] Sorry but your search for " $+ %price.item. [ $+ [ %i ] ] $+ " was not specific enough. Please narrow your search down, ie: Rune --> Rune Platelegs | /sockclose $+(price.socket.,%i) | /unset %price.*. [ $+ [ %i ] ] }  
    } 
    if (%readnextline == 1) { /set %price.displayitem. [ $+ [ %i ] ] $htmlfree(%temptext) | /set %readnextline 2 } 
    if ( *<img src="/img/member.gif"* iswm %temptext || <td class="tablebottom"><!-- Blank --></td> isin %temptext) { /set %readnextline 1 } 
    if (*Your search did not * iswm %temptext) { /notice %price.nick. [ $+ [ %i ] ] Sorry I did not find " $+ %price.item. [ $+ [ %i ] ] $+ " in the Zybez database. Please make sure you spelled everything correctly and the item you are searching for exists in Runescape. } 
  } 
} 

on *:sockclose:price.socket.*:{ /unset %price.*. [ $+ [ $right($SockName,-13) ] ] } 

alias -l htmlfree { 
  var %x, %i = $regsub($1-,/(^[^<]*>|<[^>]*>|<[^>]*$)/g,$null,%x), %x = $remove(%x,&nbsp;) 
  return %x 
}