; ––––––––––––––––––––––––––––––––––––––––
; NoNameScript v4.03 - MinIRC - coded by greeny
; Don't edit anything in here unless you REALLY know what you're doing!
; ––––––––––––––––––––––––––––––––––––––––
alias minirc {
  if (!$1) { tokenize 32 $active }
  if ($1 !ischan) && (!$query($1)) { errdialog MinIRC only works on channels and queries. }
  elseif ($window(@MinIRC)) { minirc.chg $1 }
  else {
    if (!$readini($mircini,windows,@MinIRC)) { .writeini $mkfullfn($mircini) windows @MinIRC $calc($window(-1).w -400) $+ , $+ 400 $+ , $+ $calc($window(-1).h -170) $+ ,170,0,0,1 }
    window -dok0 $+ $iif(!%minirc.disableeditbox,e) $iif(%minirc.disableborder,+fs,+fnst) @MinIRC $qt($window(Status Window).font) $int($calc($window(Status Window).fontsize *(1- %minirc.fsize)))
    setlayer %minirc.trs @MinIRC
    minirc.chg $1
  }
}
alias minirc.chgopc {
  set %minirc.trs $1
  setlayer $1 $active
}
alias minirc.targetcon { if ($1 isnum 1- $+ $scon(0)) { return $iif($wd(%minirc,2) == $scon($1),$style(1),$iif(!$chan(0) && !$query(0),$style(2))) $replace($scon($1).curconserv,$chr(123),[,$chr(125),],:,;) $+ :minirc.chgcid $scon($1) } }
alias minirc.targetchan { if ($1 isnum 1- $+ $chan(0)) { return $iif($wd(%minirc,1) == $chan($1),$style(1)) $replace($chan($1),$chr(123),[,$chr(125),],:,;) $+ :minirc.chg $chan($1) } }
alias minirc.targetquery { if ($1 isnum 1- $+ $query(0)) { return $iif($wd(%minirc,1) == $query($1),$style(1)) $replace($query($1),$chr(123),[,$chr(125),],:,;) $+ :minirc.chg $query($1) } }
alias minirc.chgcid {
  close -@ @MinIRC
  scid $1
  minirc $iif($chan(1),$v1,$query(1))
  scid -r
}
on *:nick:{
  if ($nick == $wd(%minirc,1)) && ($cid == $wd(%minirc,2)) {
    set %minirc $newnick $cid
    titlebar @MinIRC - $newnick on $curconserv
    if ($group(#tview) == on) { tview.refminirc }
    thmecho @MinIRC Target changed to $thmhl($newnick) $+ .
  }
}
alias minirc.chg {
  var %z = 1
  titlebar @MinIRC - $1 on $curconserv
  set %minirc $1 $cid
  if ($window($1)) { if ($gettok($readini($mircini,options,n2),36,44)) { filter -cwwp $1 @MinIRC } }
  else {
    if ($left($1,1) isin $chantypes) {
      thmecho @MinIRC $thmhl($1) not joined! Joining...
      %z = 0
      join -n $1
    }
    else {
      thmecho @MinIRC No query with $thmhl($1) open! Opening...
      %z = 0
      query -n $1
    }
  }
  if (%z) && ($show) { thmecho @MinIRC MinIRC window for $thmhl($1) opened on $thmhl($longtime) $+ . }
  if ($group(#tview) == on) { tview.refminirc }
}
alias minirc.actchan {
  if ($active == @MinIRC) { return $wd(%minirc,1) }
  else { return $active }
}
on *:close:@MinIRC:{ unset %minirc }
off *:input:@MinIRC:{ process.input $1- }
alias minirc.restoremirc {
  if ($window(-2).state == minimized) || ($window(-2).state == tray) { showmirc -r }
  else { showmirc -s }
}
menu @MinIRC {
  dclick:minirc.restoremirc
  $style(2) — $shorten(12,$wd(%minirc,1)) —:return
  -
  &Target
  .&Connection
  ..$submenu($minirc.targetcon($1))
  ..-
  .C&hannel
  ..$submenu($minirc.targetchan($1))
  .&Query
  ..$submenu($minirc.targetquery($1))
  -
  $iif(!$osgen,$style(2)) &Opacity
  .$submenu($minirc.opcsub($1))
  &Font size
  .$iif(!%minirc.fsize,$style(1)) &Default:minirc.chgfsize 0
  .-
  .$submenu($minirc.fsize($1))
  $iif(!%minirc.disableborder,$style(1)) &Border:minirc.toggleborder
  $iif(!%minirc.disableeditbox,$style(1)) &Editbox:minirc.toggleeditbox
  $iif(!%minirc.disabletimestamp,$style(1)) &Timestamp:minirc.toggletimestamp
  -
  C&lear:clear
  &Close:{
    unset %minirc
    window -c $active
  }
}
alias minirc.chgfsize {
  set %minirc.fsize $1
  font @MinIRC $qt($window(Status Window).font) $int($calc($window(Status Window).fontsize *(1- %minirc.fsize)))
}
alias minirc.fsize { if ($1 isnum 1-10) { return $iif(%minirc.fsize == $calc($1 *0.05),$style(1)) $+(-&,$calc($1 *5),%,:minirc.chgfsize) $calc($1 *0.05) } }
alias minirc.toggletimestamp {
  toggle minirc.disabletimestamp
  thmecho @MinIRC Timestamping $iif(%minirc.disabletimestamp,disabled!,enabled!)
}
alias minirc.toggleeditbox {
  toggle minirc.disableeditbox
  var %t = $wd(%minirc,1)
  close -@ @MinIRC
  .minirc %t
  thmecho @MinIRC Editbox $iif(%minirc.disableeditbox,disabled!,enabled!)
}
alias minirc.toggleborder {
  toggle minirc.disableborder
  var %t = $wd(%minirc,1)
  close -@ @MinIRC
  .minirc %t
  thmecho @MinIRC Border $iif(%minirc.disableborder,disabled!,enabled!)
}
alias minirc.opcsub {
  if ($1 isnum 1-10) {
    var %t = $calc(25.5* $1)
    return $iif(%minirc.trs == %t,$style(1)) $calc($1 *10) $+ % $+ :minirc.chgopc %t
  }
}
; ––––––––––––––––––––––––––––––––––––––––
; End of file
; ––––––––––––––––––––––––––––––––––––––––