DESC:Random Farter [General]
TYPE:Menus, Aliases, Events
AUTHOR:Voxx - Copyright 1998
EMAIL:Vyxx@voxx.demon.co.uk
URL:http://www.voxx.demon.co.uk
FILES:Randfart.mrc
;====================================================
;If you find farty noises humorous you should find this
;script entertaining :))))

;For best effect, get a few people together who have the script,
;all join a temporary channel like #Fart_Zone and turn the Random
;Farter on via Fart On! button in the dialogue box, after selecting
;the channel name from the To: list.

;This file should be loaded into your Remotes Window. It doesn't
;matter where the script file is located when you first load it as it
;will relocate itself into the Addins\Randfart\ folder in your mIRC
;folder automatically.

;The Fart.ZIP file needs to be unzipped into a sub-folder of your
;Wave Folder called Farts, ie, if your Wave Folder is set to
;C:\mirc\Sounds you need to create a folder called
;C:\mirc\Sounds\Farts\ and unzip the file into it.

;This fine example of mIRC Scripting was cobbled together by
;Voxx on a boring Saturday afternoon in September 1998.

;Further Fart packs to be available shortly for your further farting
;pleasure - each pack contains 100 brand spanking new never
;heard before farts, lovingly created by me, using my secret
;recipie :)

;Any comments or problems, email me at the address up at the top.

;Happy Farting :)

;13.1.99 - Upgraded it for use with mIRC 5.5 - a Dialogue box added!
;14.9.98 - Now supports Farting Frenzy Mode !!
;16.8.98 - Added Count Farts option - should speed up fart access!
;====================================================
ON *:LOAD {
  Countfarts
  Sed RandomSeedTime 30
  Sed FrenzyLength 50
  Sed DialogXY -1 -1
}
;====================================================
CTCP *:FARTFRENZY! { Playfartrandomly 2 $IIF($CHAN != $NULL,$CHAN,$NICK) 0 }
;====================================================
MENU CHANNEL,QUERY,MENUBAR {
  Random Farts ...:Dorandomfartsbox
}
;====================================================
;<type> <target> [count]
ALIAS -l Playfartrandomly {
  SET -u0 %vyxx.fartc $Ge(MaxFarts)
  IF (%vyxx.fartc == 0) || (%vyxx.fartc == $NULL) { ECHO -t $2 Random Farter No Farts Found ! | RETURN }
  SET -u0 %vyxx.fartf fart $+ $RAND(1,%vyxx.fartc) $+ .wav
  SET -u0 %vyxx.fartt $INT( $CALC( $Ge(RandomSeedTime) - ($RAND(1,$Ge(RandomSeedTime)) - ($Ge(RandomSeedTime) / 2)) ) )
  IF $1 == 0 { ECHO -t $2 Random Farter Expelling $NOPATH(%vyxx.fartf) | Dofart $2 %vyxx.fartf | RETURN }
  IF $1 == 1 { .TIMERRandomfarter -o 1 %vyxx.fartt Playfartrandomly 1 $2 }
  IF $1 == 2 {
    IF $3 > $Ge(FrenzyLength) { ECHO -t $2 Random Farter Frenzy Mode Deactivated! | RETURN }
    IF $3 == 0 { ECHO -t $2 Random Farter Frenzy Mode Activated! }
    IF $INWAVE != $TRUE { Dofart $2 %vyxx.fartf 1 }
    .TIMER -m 1 500 Playfartrandomly 2 $2 $CALC($3 + 1) | RETURN
  }
  Dofart $2 %vyxx.fartf
}
;<target> <fart_file> [flag]
ALIAS -l Dofart {
  IF $3 == $NULL { IF $SERVER != $NULL { .SOUND $1 $2 | RETURN } }
  .SPLAY $2
}
;<target>
ALIAS -l Dofartfrenzy {
  IF $SERVER != $NULL { .CTCP $1 FARTFRENZY! }
  Playfartrandomly 2 $1 0
}
ALIAS -l Countfarts {
  SET -u0 %vyxx.fartc $FINDFILE($WAVEDIRFarts,fart*.wav,0)
  Se MaxFarts %vyxx.fartc
}
ALIAS -l Dorandomfartsbox { DIALOG -m Randfarter Randomfartsdialog | DIALOG -s Randfarter $Ge(DialogXY) 200 230 }
;====================================================
ALIAS -l Toggle { IF $Ge($1) == ON { Se $1 OFF } | ELSE { Se $1 ON } }
ALIAS -l Ge { RETURN $READINI $SCRIPTDIRRandfart.ini Setting $1 }
ALIAS -l Re { REMINI $SCRIPTDIRRandfart.ini Setting $1- }
ALIAS -l Se { WRITEINI $SCRIPTDIRRandfart.ini Setting $1 $2- }
ALIAS -l Sed {
  SET -u0 %vyxx.farttemp $READINI $SCRIPTDIRRandfart.ini Setting $1
  IF %vyxx.farttemp == $NULL { WRITEINI $SCRIPTDIRRandfart.ini Setting $1 $2- }
}
;====================================================
DIALOG Randomfartsdialog {
  SIZE -1 -1 200 230
  TITLE "Random Farter"
  BUTTON "&Close",1,73 200 55 25,CANCEL
  BUTTON "&Fart On!",2,15 15 55 25
  TEXT "To:",3,75 20 30 15
  COMBO 4,95 17 92 90,DROP
  BUTTON "F&renzy!",5,15 45 55 25
  TEXT "To:",6,75 50 30 15
  COMBO 7,95 47 92 90,DROP
  BUTTON "S&ingle",8,15 75 55 25
  TEXT "To:",9,75 80 30 15
  COMBO 10,95 77 92 90,DROP
  BUTTON "C&ount",11,15 105 55 25
  TEXT "",12,95 110 80 15
  TEXT "Fart Time:",13,20 140 50 15
  COMBO 14,95 135 92 90,DROP
  TEXT "Frenzy Time:",15,20 170 80 15
  COMBO 16,95 165 92 90,DROP
  BOX "",17,5 0 190 194
}
ON 1:DIALOG:Randfarter:INIT:* {
  SET -u0 %vyxx.randfarttemp 0
  :loop
  INC %vyxx.randfarttemp 1
  IF $CHAN(%vyxx.randfarttemp) == $NULL { GOTO end }
  DID -i Randfarter 4 %vyxx.randfarttemp $CHAN(%vyxx.randfarttemp)
  IF $CHAN(%vyxx.randfarttemp) == $Ge(FartTarget) { DID -c Randfarter 4 %vyxx.randfarttemp }
  DID -i Randfarter 7 %vyxx.randfarttemp $CHAN(%vyxx.randfarttemp)
  DID -i Randfarter 10 %vyxx.randfarttemp $CHAN(%vyxx.randfarttemp)
  GOTO loop
  :end
  IF $TIMER(Randomfarter) != $NULL { DID -o Randfarter 2 1 &Stop It! | DID -b Randfarter 4 }
  IF $DID(4) == $NULL { DID -c Randfarter 4 1 }
  DID -c Randfarter 7 1
  DID -c Randfarter 10 1
  DID -a Randfarter 12 Found: $Ge(MaxFarts)
  SET -u0 %vyxx.randfarttemp 0
  :loop2
  INC %vyxx.randfarttemp 1
  IF %vyxx.randfarttemp > 10 { GOTO end2 }
  DID -i Randfarter 14 %vyxx.randfarttemp $CALC(%vyxx.randfarttemp * 15)
  IF $Ge(RandomSeedTime) == $CALC(%vyxx.randfarttemp * 15) { DID -c Randfarter 14 %vyxx.randfarttemp }
  GOTO loop2
  :end2
  SET -u0 %vyxx.randfarttemp 0
  :loop3
  INC %vyxx.randfarttemp 1
  IF %vyxx.randfarttemp > 10 { GOTO end3 }
  DID -i Randfarter 16 %vyxx.randfarttemp $CALC(%vyxx.randfarttemp * 10)
  IF $Ge(FrenzyLength) == $CALC(%vyxx.randfarttemp * 10) { DID -c Randfarter 16 %vyxx.randfarttemp }
  GOTO loop3
  :end3
}

ON 1:DIALOG:Randfarter:SCLICK:2 {
  IF (&Fart On! == $DID(2)) {
    IF $DID(4).SEL == $NULL { RETURN }
    DID -o Randfarter 2 1 &Stop It! | DID -b Randfarter 4
    Playfartrandomly 1 $DID(4,$DID(4).SEL)
    Se FartTarget $DID(4,$DID(4).SEL)
  }
  ELSE {
    DID -o Randfarter 2 1 &Fart On! | DID -e Randfarter 4
    .TIMERRandomfarter OFF
    Re FartTarget
  }
}
ON 1:DIALOG:Randfarter:SCLICK:5 { Dofartfrenzy $DID(7,$DID(7).SEL) }
ON 1:DIALOG:Randfarter:SCLICK:8 { Playfartrandomly 0 $DID(10,$DID(10).SEL) }
ON 1:DIALOG:Randfarter:SCLICK:11 { DID -r Randfarter 12 | DID -a Randfarter 12 Counting Farts ... | Countfarts | DID -r Randfarter 12 | DID -a Randfarter 12 Found: $Ge(MaxFarts) }
ON 1:DIALOG:Randfarter:SCLICK:14 { Se RandomSeedTime $DID(14,$DID(14).SEL) }
ON 1:DIALOG:Randfarter:SCLICK:16 { Se FrenzyLength $DID(16,$DID(16).SEL) }