alias nl { dialog -m NickListView NickListView }
dialog NickListView {
  title "Connection Manager by Tommy"
  size 629 68 250 160
  option dbu
  list 1, 1 2 248 143,size
  button "Kill", 2, 170 146 37 12
  button "Gline", 3, 211 146 37 12
  button "Clear", 5, 1 146 37 12
  edit "Bot", 4, 40 146 128 12
}

on *:dialog:NickListView:*:*: {
  if ($devent == init) {
    mdx SetControlMDX $dname 1 ListView report rowselect single showsel grid  > script\dlls\views.mdx
    did -i $dname 1 1 headerdims 100 350
    did -i $dname 1  1 headertext Nick $chr(9) Hostname 
    initlist
  }
  if ($devent == sclick) {
    if ($did == 2) kill $gettok($did(1).seltext,6,32) $did(4)
    if ($did == 3) gline $gettok($did(1).seltext,6,32) 0 $did(4)
    if ($did == 5) did -r NickListView 1
    if ($did == 1) {
      tokenize 32 $did(1,1)
      if ($1 = headerclick) sxsort $dname $did $3
    }
  }
}

alias initlist {
  set %initting $true 
  .msg operserv userlist
}

on ^1:notice:*:*: {
  if (%initting == $true) && ($nick == OperServ) {
    if ($1 == Users) && ($2 == list:) { halt } 
    if ($1 == Nick) && ($2 == Mask) { halt } 
    if ($1 == End) && ($2 == of) { set %initting $false | halt } 
    did -a NickListView 1 $1 $chr(9) $2
    halt
  }
}

on *:servermode:#:if ($1 == +i ) dialog -v NickListView

alias getid {
  %i = 2
  while (%i < $calc($did(NickListView,1).lines + 1))  {
    %line = $did(NickListView,1,%i).text
    if ( $gettok(%line,6,32) == $1) return %i
    %i = %i + 1
  }
}

on *:snotice:*: { 
  if ($5 == connecting) did -i NickListView 1 2 $9 $chr(9) $replace($10,$chr(40),,$chr(41),)
  if ($5 = exiting:) did -d NickListView 1 $getid($6)
}