# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit eutils games

DESCRIPTION="Single & multiplayer mod adding older iD Software characters"
HOMEPAGE="http://hosted.planetquake.gamespy.com/sog/
	http://planetquake.gamespy.com/View.php?view=MOTW.Detail&id=51"
# SOG 1.3 is a Windows executable, so stay with 1.2
SRC_URI="sog12full.zip
	SOG.tar.bz2"

LICENSE="as-is"
SLOT="0"
KEYWORDS=""
IUSE="debug"
RESTRICT="fetch"

# Tested with the qudos engine - other engines might work also
RDEPEND="games-fps/qudos
	games-fps/quake2-data"
DEPEND="app-arch/unzip"

S=${WORKDIR}/SOG/src
libdir=${GAMES_LIBDIR}/qudos/sog

pkg_nofetch() {
	einfo "Please download:"
	einfo "   http://qudos.quakedev.com/linux/quake2/mods/SOG.tar.bz2"
	einfo "   sog12full.zip from http://www.extreme-players.de/download.php?id=3092"
	einfo "and place them in ${DISTDIR}"
}

src_unpack() {
	unpack ${A}

	find . '(' -name '*.dll' -o -name '*.exe' ')' | xargs rm -f

	# Music doesn't work, so disable it
	sed -i \
		-e "s:music 1:music 0:" \
		sog/autoexec.cfg || die "sed autoexec.cfg failed"

	cd "${S}"

	# Ensure the Makefile's CFLAGS are clean, otherwise get seg. fault
	sed -i \
		-e "s:-ffast-math::" \
		-e "s:-fomit-frame-pointer::" \
		Makefile || die "sed Makefile failed"
}

src_compile() {
	local target="release"
	use debug && target="debug"

	make \
		BUILD_DEBUG_DIR=release \
		BUILD_RELEASE_DIR=release \
		${target} || die "emake release failed"
}

src_install() {
	exeinto "${libdir}"
	# Compiled:
	doexe release/sog/*.so || die
	# Pre-compiled:
	#doexe "${WORKDIR}"/SOG/sog/*.so || die

	insinto "${libdir}"
	doins -r "${WORKDIR}"/sog/* || die

	# baseq2 goes into sog dir also, to keep the mod separate from vanilla
	insinto "${libdir}"
	doins -r "${WORKDIR}"/baseq2/* || die

	# sog0 is the intro movie map
	games_make_wrapper ${PN} "qudos +set game sog +map sog0"
	make_desktop_entry ${PN} "QuDos - Some Other Game" qudos.xpm

	prepgamesdirs
}

pkg_postinst() {
	games_pkg_postinst

	elog "Customize the SOG-specific keys in:"
	elog "   ${libdir}/autoexec.cfg"
	echo
}