divert(-1)
# $Id: sendmail.mc,v 1.29 2003/11/27 18:54:09 jmates Exp $
#
# Configuration for an optional localhost-only sendmail daemon that
# client applications can deliver mail to via SMTP on the localhost
# interface.  All mail will be passed to the central MX servers for the
# domain by default.  Mail submitted on the command line is processed by
# sendmail running with the submit.cf configuration, not sendmail.cf.
#
# See sendmail's cf/README file for documentation on how to adjust this
# file to suit your needs.
#
# To build sendmail.cf from this file, configure the Makefile for the
# system in question, then run 'make config reload' to rebuild the
# configuration files and restart Sendmail.
divert(0)

dnl adjust following for system in question (darwin, linux, solaris2 are
dnl common; see the cf/ostype directory for others).
OSTYPE(`linux')


dnl disable aliases, .forward on dumb clients
undefine(`ALIAS_FILE')
define(`confFORWARD_PATH', `')

dnl Only allow user@example.org addresses.  Central mail servers
dnl consequently need to handle all accounts for the domain.
MASQUERADE_AS(`coker.edu')
MASQUERADE_DOMAIN(`coker.edu')
dnl MASQUERADE_EXCEPTION(`lists.example.org')

FEATURE(`allmasquerade')
FEATURE(`masquerade_envelope')
FEATURE(`masquerade_entire_domain')

FEATURE(`always_add_domain')

dnl all mail sent to central MX hosts for domain
define(`LOCAL_RELAY', `pascal.coker.edu.')
define(`MAIL_HUB', `pascal.coker.edu.')
define(`SMART_HOST', `pascal.coker.edu.')
dnl alternative to SMART_HOST for open networks is to have a fallback
dnl define(`confFALLBACK_MX', `example.org.')


dnl TLS configuration
dnl disabled by default, as Sendmail must be compiled with STARTTLS support

dnl define(`CERT_DIR', `MAIL_SETTINGS_DIR`'certs')
dnl define(`confCACERT', `CERT_DIR/cacert.pem')
dnl define(`confCACERT_PATH', `CERT_DIR/CA')
dnl define(`confSERVER_CERT', `CERT_DIR/host.cert')
dnl define(`confSERVER_KEY',  `CERT_DIR/host.key')
dnl define(`confCLIENT_CERT', `CERT_DIR/host.cert')
dnl define(`confCLIENT_KEY',  `CERT_DIR/host.key')

dnl For TLS, the smmsp user will need read access to the confSERVER_KEY
dnl file, which can be done with a chgrp smmsp and a chmod g+r on the file
dnl plus the following.  Allow group writable directories due to lax
dnl permissions on certain client OS (Mac OS X, for instance).
define(`confDONT_BLAME_SENDMAIL', `GroupWritableDirPathSafe,GroupReadableKeyFile')


dnl only listen on localhost interface, for SMTP from local programs
DAEMON_OPTIONS(`Family=inet, address=127.0.0.1, Name=MTA')
FEATURE(`no_default_msa')
DAEMON_OPTIONS(`Family=inet, address=127.0.0.1, Port=587, Name=MSA, M=E')

dnl enable these for IPv6 support
dnl DAEMON_OPTIONS(`Family=inet6, address=::1, Name=MTA6, M=O')
dnl DAEMON_OPTIONS(`Family=inet6, address=::1, Port=587, Name=MSA6, M=O, M=E')
dnl define(`confBIND_OPTS', `WorkAroundBrokenAAAA')

dnl prevent huge files being used as DoS attack
define(`confMAX_MESSAGE_SIZE', `5242880')

dnl clients should be able to see queue
define(`confPRIVACY_FLAGS', ``goaway,restrictqrun'')

dnl do not wait for ident
define(`confTO_IDENT', `0')

dnl disable statistics if not using mailstats(8)
define(`STATUS_FILE', `')

dnl turn off various protocols: SMTP only by default
undefine(`UUCP_RELAY')
undefine(`BITNET_RELAY')
undefine(`DECNET_RELAY')
undefine(`FAX_RELAY')
FEATURE(`nouucp', `reject')

dnl set this to queue mail by default, e.g. for dial-up or laptop
dnl define(`confDELIVERY_MODE', `deferred')

MAILER(`smtp')