on $*:TEXT:/^[!@](setname|defname)/Si:#:{
  writeini idlenames.ini Nicks $address($nick,2) $2-
  .notice $nick $c2(Your default name for) $c1($address($nick,2)) $c2(has been set to) $c1($2-)
}
on $*:text:/^[!@](idle|idlestats)/Si:#: {  
  set %idle.way $iif($left($1,1) == @, .msg $chan, .notice $nick) 
  if (!$2) && ($readini(idlenames.ini,n,Nicks,$address($nick,2))) {
    set %idle.nick $readini(idlenames.ini,n,Nicks,$address($nick,2))
  }
  elseif (!$2) { set %idle.nick $nick
  }
  else {
    set %idle.nick $2- 
  }
  sockopen IRPG www.xnemesis.net 80 
} 
on *:SOCKOPEN:IRPG: { 
  sockwrite -nt $sockname GET /superirc/irpg/playerview.php?player= $+ %idle.nick
  sockwrite -nt $sockname Host: www.xnemesis.net 
  sockwrite -nt $sockname $crlf $crlf 
} 
on *:SOCKREAD:IRPG: { 
  if ($sockerr) { echo -at ** Error ** in scoket: $sockerr | halt } 
  else { 
    var %sockreader 
    sockread %sockreader
    if (*<b>No such user.</b>* iswm %sockreader) {
      %idle.way $c2(ERROR: User) $c1(%idle.nick) $c2(was not found.) | unset %idle.* | set %idle.wrong 1 | halt
    }
    if (*<b>Level:</b>* iswm %sockreader) { 
      tokenize 32 %sockreader 
      set %idle.lvl $nohtml($2)
    } 
    if (*<b>Class:</b>* iswm %sockreader) {
      tokenize 32 %sockreader 
      set %idle.class $nohtml($2-)
    } 
    if (*<b>Next level:</b>* iswm %sockreader) {
      tokenize 32 %sockreader 
      set %idle.nxtlvl $nohtml($remove($2-,level:))
    }
    if (*<b>Total time idled:</b>* iswm %sockreader) {
      tokenize 32 %sockreader 
      set %idle.total $nohtml($remove($2-,time idled:))
    }
    if (*sum:* iswm %sockreader) {
      tokenize 32 %sockreader
      set %idle.sum $nohtml($2-)
    }  
    if (*<b>Status:</b>* iswm %sockreader) {
      tokenize 32 %sockreader 
      set %idle.status $nohtml($2-)
    }
    if (*[<font color="#be9256">* iswm %sockreader) {
      tokenize 32 %sockreader
      set %idle.specits $nohtml($2-)
    }
    if (*<b>Alignment:</b>* iswm %sockreader) {
      tokenize 32 %sockreader 
      set %idle.align $nohtml($2-)
    }
    if ($regex(%sockreader,.(0[1-9]|1[012])[/](0[1-9]|[12][0-9]|3[01])[/]07)) {
      tokenize 32 %sockreader
      set %idle.charmods $nohtml([ $+ $2-)
    }
  }
}
on *:sockclose:IRPG: {
  if ($var(%idle.wrong)) {
    unset %idle.wrong | halt
  }
  else {
    %idle.way $c2(Player info for :**) $c1(%idle.nick) $c2(**:) 
    %idle.way $c2(Level:) $c1(%idle.lvl) $c2(Next level in:) $c1(%idle.nxtlvl) $c2(Total Time Idled:) $c1(%idle.total) $c2(Class:) $c1(%idle.class) $c2(Item Sum:) $c1(%idle.sum) $c2(Status:) $c1(%idle.status) $c2(Alignment:) $c1(%idle.align) 
    %idle.way $c2(Recent Character Modifications:) $c1(%idle.charmods) 
    if ($var(%idle.specits)) {
      %idle.way $c2(Special Items:) $c1(%idle.specits)
    }
    else {
      %idle.way $c2(Special Items:) $c1(NONE)
    }
    unset %idle.*
  }
}
alias nohtml { var %x,%i = $regsub($1-,/(^[^<]*>|<[^>]*>|<[^>]*$)/g,$null,%x) | %x = $replace(%x,&nbsp;,$null) | return %x }
alias c1 { return $+($chr(3),04,$1-) }
alias c2 { return $+($chr(3),14,$1-) }