; ––––––––––––––––––––––––––––––––––––––––
; NoNameScript v4.03 - script startup - coded by greeny
; Don't edit anything in here unless you REALLY know what you're doing!
; ––––––––––––––––––––––––––––––––––––––––
alias startup {
!window -adohfk0p +fL @StartupLogo $int($calc($window(-1).w /2+ $window(-1).x -165)) $int($calc($window(-1).h /2+ $window(-1).y -173)) 330 246
drawpic @StartupLogo 0 0 script\pics\nnscript.jpg
!window -adohfk0p +fL @StartupInfo $int($calc($window(-1).w /2+ $window(-1).x -165)) $int($calc($window(-1).h /2+ $window(-1).y +90)) 330 50
startup.drawcube
drawtext @StartupInfo $color(normal) Tahoma 10 55 5 • Loading NoNameScript %version for the $ord(%stat.scriptstarts) time.
.timerstartup.close -io 1 5 startup.close
}
alias startup.drawcube {
if (!$window(@StartupInfo)) { .timerstartup.drawcube off }
else {
if (!%cube.y) {
set %cube.y $calc($1)
set %cube.p $calc($2)
set %cube.r $calc($3)
}
drawrect -nf @StartupInfo $color(back) 1 0 0 50 50
var %v = 0
while (%v < 8) {
set %cube. [ $+ [ %v ] ] $startup.calc3d(%v,10)
inc %v
}
drawline -n @StartupInfo $color(normal) 1 %cube.1 %cube.5 %cube.7 %cube.3 %cube.1
drawline -n @StartupInfo $color(normal) 1 %cube.5 %cube.4 %cube.6 %cube.7 %cube.5
drawline -n @StartupInfo $color(normal) 1 %cube.4 %cube.0 %cube.2 %cube.6 %cube.4
drawline -n @StartupInfo $color(normal) 1 %cube.0 %cube.1 %cube.3 %cube.2 %cube.0
drawdot @StartupInfo
inc %cube.y 4
inc %cube.p 2
inc %cube.r 1
.timerstartup.drawcube -h 1 0 startup.drawcube
}
}
alias startup.calc3dbs { return $+($iif($mid($base($1,10,2,3),$2,1),-),$3) }
alias startup.calc3d {
var %cube.x1,%cube.x2,%cube.x3,%cube.y1,%cube.y2,%cube.y3,%cube.z1,%cube.z2,%cube.z3,%cube.1 = $startup.calc3dbs($1,1,10),%cube.2 = $startup.calc3dbs($1,2,10),%cube.3 = $startup.calc3dbs($1,3,10)
%cube.x1 = $calc((%cube.3 * $sin(%cube.y).deg)+(%cube.1 * $cos(%cube.y).deg))
%cube.y1 = %cube.2
%cube.z1 = $calc((%cube.3 * $cos(%cube.y).deg)-(%cube.1 * $sin(%cube.y).deg))
%cube.x2 = %cube.x1
%cube.y2 = $calc((%cube.y1 * $cos(%cube.p).deg)-(%cube.z1 * $sin(%cube.p).deg))
%cube.z2 = $calc((%cube.y1 * $sin(%cube.p).deg)+(%cube.z1 * $cos(%cube.p).deg))
%cube.x3 = $calc((%cube.y2 * $sin(%cube.r).deg)+(%cube.x2 * $cos(%cube.r).deg))
%cube.y3 = $calc((%cube.y2 * $cos(%cube.r).deg)-(%cube.x2 * $sin(%cube.r).deg))
inc %cube.x3 25
inc %cube.y3 25
return %cube.x3 %cube.y3
}
alias startup.close {
.timerstartup.* off
unset %cube.*
close -@ @StartupLogo @StartupInfo
}
alias firststart {
if ($window(@StartupLogo)) { close -@ $v1 }
if ($window(@StartupInfo)) { close -@ $v1 }
idialog You are running the script for the first time. Please take some time to set it up.
setup
}
menu @StartupLogo {
sclick:startup.close
}
menu @StartupInfo {
sclick:startup.close
}
on *:start:{
if ($version != 6.17) {
errdialog you need mIRC v6.17 to use this script. However, you are using $+(v,$version,.) Please get the correct version at http://www.nnscript.de!
url -an http://www.mirc.com/get.html
exit
halt
}
if ($os == 95) {
errdialog you are using Windows95, which is no longer supported by NoNameScript. Please upgrade your windows installation to use this script.
exit
halt
}
if (!$chkmdir) {
errdialog please don't launch NoNameScript from directories with two or more successive spaces in them. Rename the directory and re-start the script.
exit
halt
}
if ($disk($left($mircdir,1)).free < 20971520) { idialog Warning: there is only $bytes($v1,3).suf of free space available on drive $left($mircdir,2) $+ ! If you run out of free disk space, the script will not work as intended. Please free up some disk space and re-start the script. }
if ($lock(run)) || ($lock(dll)) || ($lock(com)) || ($lock(decode)) {
errdialog you have locked one or more of the /run, /dll, /com or $decode commands in the mIRC options (ALT+O, "Other", "Lock"). NoNameScript needs these commands to work. Please unlock these features and re-start mIRC. The script has been halted.
if (!$lock(dll)) { nndll sendkey ALT O }
halt
}
var %st = $nn.ticks,%upd
if (!%nocrash) { inc %stat.scriptcrashes }
unset %nocrash
loadhash
inc %stat.scriptstarts
if (%ssplash) { startup }
dll script\dlls\winevent.dll Load .
if (%tview.enabled) { tview }
if (%winarr.auto) { .timer 1 0 winarr.apply %winarr }
winpic Status Window
nndll seticon $mkfullfn(script\pics\nn.ico).noqt
.ial on
.timestamp -f $thmdata(%thm.current,timestamp)
.timestamp -g $thmdata(%thm.current,timestamp)
tokenize 58 %alarm.time
if (%alarm.mode == 1) && (%alarm.eday) && ($1 isnum 0-23) && ($2 isnum 0-59) { .timeralarm -io $+($1,:,$2) 1 0 alarm.ring $chr(124) .timeralarmre 1 300 .timeralarm -io $+($1,:,$2) 1 0 alarm.ring }
.timerdc -io 0:00 1 0 chgday
if (%ban.mask == $null) { set %ban.mask 3 }
if (%ignore.mask == $null) { set %ignore.mask 3 }
if (%lb.enabled) {
toolbar
if (%lb.bar) { lagchktimer }
}
if (%email.checker) {
.timermailchk -io 0 $iif(%mail.delay,$v1,600) checkmail
checkmail
}
unsetvars
set %lastcid $cid
set %appactive $!true
titlebar.ctmr
.timerrecuptime -io 0 60 sysinfo.chkuptimerecord
if (%stat.scriptstarts == 1) {
set %thm.forcerefresh 1
.thmload -s28 themes\winter.nnt
set %install.time $ctime
set %stat.lastreset $ctime
set %getexternalip 1
.copy -o script\txt\kickmsg.txt script\txt\kickmsg-def.txt
.copy -o script\txt\quitmsg.txt script\txt\quitmsg-def.txt
.copy -o script\txt\slaps.txt script\txt\slaps-def.txt
.timer 1 0 firststart
}
if (%version < 4.02) {
var %z = $var(%cprot.*.caps.percent,0)
while (%z) {
set [ $var(%cprot.*.caps.percent,%z) ] $calc(1- [ [ $var(%cprot.*.caps.percent,%z) ] ] )
dec %z
}
fkey.ldef
}
if (%version < 4.03) {
set %version 4.03
set %nntversion 1.02
noop $findfile(themes\,*.nnt,0,0,thm102update $qt($1-))
.unload -rs script\sbar.nns
var %z = $var(%mailacc.*,0)
while (%z) {
set [ $var(%mailacc.*,%z) ] [ [ $var(%mailacc.*,%z) ] ] 0
dec %z
}
noop $read(script\txt\quitmsg.txt,n,www.nnscript.de)
if ($readn) { write -l $+ $v1 script\txt\quitmsg.txt 12( www.nnscript.de 12:: NoNameScript 4.03 12:: www.XLhost.de 12) }
.thmprevclear
set %thm.forcerefresh 1
.thmload $iif(%thm.scheme,-s $+ $v1) %thm.current
%upd = 1
}
if (!$thmvchk(%thm.current)) {
if ($thmvchk(themes\winter.nnt)) {
.thmload -s28 themes\winter.nnt
.timer 1 0 errdialog since the theme file you have previously loaded doesn't exist anymore, the default theme has been loaded.
}
else { .timer 1 0 errdialog your themes have been corrupted. Please re-install the default theme (Winter) or NoNameScript. }
}
if (%thm.lrand) { .thm.lrand }
if (%qcls.auto) { .timerqcls -io 0 30 scon -a chkqcls }
if (%rssticker) { .timernwstick -io 0 $calc(%nwstick.mins *60) newsticker }
if (%anti.idle) { .timeraidle -io 0 %aidle.max scon -at1 aidle }
.thmupd
thmls -s
if (%upd) { thmecho -s NoNameScript has been successfully updated to version $thmhl(%version) $+ . }
thmecho -s Finished loading NoNameScript $thmhl(%version) with mIRC $thmhl($version) in $thmhl($round($calc(($nn.ticks - %st)/1000),2)) second(s).
if (!%ssplash) {
thmecho -s Running version $thmhl(%version) with mIRC $thmhl($version) for the $thmhl($ord(%stat.scriptstarts)) time.
thmecho -s Using $thmhl($thmdata(%thm.current,name) $thmdata(%thm.current,version)) theme $iif(%thm.scheme,with $thmhl($schmprt($thmdata(%thm.current,Scheme $+ %thm.scheme)).name scheme)) by $thmhl($thmdata(%thm.current,author)) $+ .
}
elseif ($window(@StartupInfo)) {
drawtext @StartupInfo $color(normal) Tahoma 10 55 18 • Finished loading in $round($calc(($nn.ticks - %st)/1000),2) $+ s.
drawtext @StartupInfo $color(normal) Tahoma 10 55 31 • Using $thmdata(%thm.current,name) $thmdata(%thm.current,version) theme $+ $iif(%thm.scheme,$chr(32) $nbr($schmprt($thmdata(%thm.current,Scheme $+ %thm.scheme)).name scheme)) $+ .
}
if (%totd) {
var %totd = $read(script\txt\totd.txt,n)
thmecho -a Did you know? $thmhl($chr(35) $+ $readn) $+ : %totd
}
if (%checkver.startup) { .checkver }
var %z,%i = 1,%t = $wd(%autoconservs,0)
if ($specialday) { thmecho -s $v1 }
thmls -s
echo -s 
while (%i <= %t) {
var %s = $wd(%autoconservs,%i)
if ($wd(%autoconserv. [ $+ [ %s ] ],4)) {
if (!%z) { thmecho -s Connecting to set-up networks... hold shift to skip perform! }
thmecho -s Connecting to $thmhl(%s) $+ ...
server $iif(%z,-m) %s
%z = 1
}
inc %i
}
if (%z) { echo -s  }
return
:error
errdialog an error occured while loading the script: $error
reseterror
}
; ––––––––––––––––––––––––––––––––––––––––
; End of file
; ––––––––––––––––––––––––––––––––––––––––