on 1:start:{
  .timer 1 60 idmd5_updatecheck
  .timer 0 10800 idmd5_updatecheck
}
alias idmd5_updatecheck {
  unset %idmd5_latest
  var %a = 0
  if ($sock(idmd5_updatecheck)) { sockclose idmd5_updatecheck | var %a = 5 }
  .timer 1 %a sockopen idmd5_updatecheck xdominionx.com 80
}
on *:sockopen:idmd5_updatecheck:{ 
  if ($sockerr) { return }
  sockwrite -n $sockname GET /stobo/StoboAccessUpdateCheck.php HTTP/1.1 
  sockwrite -n $sockname Host: xdominionx.com $+ $crlf $+ $crlf
}
on *:sockread:idmd5_updatecheck:{
  var %a
  sockread %a
  if (ScriptMD5 isin %a) { %idmd5_latest = $gettok(%a,2,32) }
}
on *:sockclose:idmd5_updatecheck: {
  if (%idmd5_latest && $md5($script,2) != %idmd5_latest) { idmd5_UpdateAvailable yes | return }
  idmd5_UpdateAvailable no
}

alias idmd5_UpdateAvailable {
  if ($1 == yes) { Echo -as 0,111An update/restore is available for your StoboAccess.mrc script. To get it right click in a channel and go to: Stobo> Update> Get Script Update. }
  if ($1 == No && %idmd5_ManUpdateCheck == yes) { echo -a 0,111Your StoboAccess.mrc script is up to date. | unset %idmd5_ManUpdateCheck }
}

alias idmd5_GetUpdate {
  var %a = 0
  if ($sock(idmd5_GetUpdate)) { sockclose idmd5_GetUpdate | var %a = 5 }
  .timer 1 %a sockopen idmd5_GetUpdate xdominionx.com 80
}
on *:sockopen:idmd5_GetUpdate:{
  unset %idmd5H
  if ($sockerr) { return }
  .remove StoboAccess.tmp
  sockwrite -n $sockname GET /stobo/StoboAccess.mrc HTTP/1.1 
  sockwrite -n $sockname Host: xdominionx.com $+ $crlf $+ $crlf
}
on *:sockread:idmd5_GetUpdate:{
  if (!%idmd5H) { 
    sockread %data
    if (!%data) { %idmd5H = set }
    return
  }
  sockread &Data
  while ($sockbr) {
    bwrite StoboAccess.tmp -1 $ifmatch &Data
    sockread &Data
  }
}
on *:sockclose:idmd5_GetUpdate:{
  if (%idmd5_latest == $md5(StoboAccess.tmp,2)) {
    .echo -a 0,111StoboAccess.mrc has been downloaded and installed successfully. You are up to date.
    .remove $+(",$script,")
    .rename StoboAccess.tmp $+(",$script,")
    .reload -rs $+(",$script,")
  }
}