AC_PREREQ(2.57)

AC_INIT([beryl-core],esyscmd(. ./VERSION;echo -n $VERSION), [livinglatexkali@gmail.com])

AC_DEFINE_UNQUOTED(VERSION,"$VERSION",[Version])

#AC_CONFIG_AUX_DIR(config)

AM_INIT_AUTOMAKE([1.9 dist-bzip2])

AC_CONFIG_HEADER([config.h])
AM_MAINTAINER_MODE

AC_ISC_POSIX
AC_PROG_CC
AC_PROG_CPP
AC_PROG_LIBTOOL
AC_HEADER_STDC
AC_CHECK_HEADERS([stdlib.h sys/time.h unistd.h])
IT_PROG_INTLTOOL([0.35.0])
AC_SUBST(ALL_LINGUAS)
AM_GLIB_GNU_GETTEXT
GETTEXT_PACKAGE=beryl-core
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Gettext package.])
AC_SUBST(GETTEXT_PACKAGE)

if test "x$GCC" = "xyes"; then
  case " $CFLAGS " in
  *[[\ \ ]]-Wall[[\ \   ]]*) ;;
  *) CFLAGS="$CFLAGS -Wall" ;;
  esac

  case " $CFLAGS " in
  *[[\ \ ]]-Wpointer-arith[[\ \  ]]*) ;;
  *) CFLAGS="$CFLAGS -Wpointer-arith" ;;
  esac

  case " $CFLAGS " in
  *[[\ \ ]]-Wstrict-prototypes[[\ \ ]]*) ;;
  *) CFLAGS="$CFLAGS -Wstrict-prototypes" ;;
  esac

  case " $CFLAGS " in
  *[[\ \ ]]-Wmissing-prototypes[[\ \   ]]*) ;;
  *) CFLAGS="$CFLAGS -Wmissing-prototypes" ;;
  esac

  case " $CFLAGS " in
  *[[\ \ ]]-Wmissing-declarations[[\ \ ]]*) ;;
  *) CFLAGS="$CFLAGS -Wmissing-declarations" ;;
  esac

  case " $CFLAGS " in
  *[[\ \ ]]-Wnested-externs[[\ \ ]]*) ;;
  *) CFLAGS="$CFLAGS -Wnested-externs" ;;
  esac

  case " $CFLAGS " in
  *[[\ \ ]]-fno-strict-aliasing[[\ \   ]]*) ;;
  *) CFLAGS="$CFLAGS -fno-strict-aliasing" ;;
  esac

  if test "x$enable_ansi" = "xyes"; then
    case " $CFLAGS " in
    *[[\ \  ]]-ansi[[\ \   ]]*) ;;
    *) CFLAGS="$CFLAGS -ansi" ;;
    esac

    case " $CFLAGS " in
    *[[\ \  ]]-pedantic[[\ \  ]]*) ;;
    *) CFLAGS="$CFLAGS -pedantic" ;;
    esac
  fi
fi

AC_C_BIGENDIAN

plugindir=$libdir/beryl
AC_SUBST(plugindir)

imagedir=$datadir/beryl
AC_SUBST(imagedir)

LIBBERYLDECORATION_REQUIRES="xrender >= 0.8.4"
PKG_CHECK_MODULES(LIBBERYLDECORATION, $LIBBERYLDECORATION_REQUIRES)
AC_SUBST(LIBBERYLDECORATION_REQUIRES)

BERYL_REQUIRES="libpng \
xcomposite >= 0.3 \
xfixes \
xdamage \
xrandr \
ice \
sm \
xinerama \
libstartup-notification-1.0 >= 0.7"

PKG_CHECK_MODULES(BERYL, $BERYL_REQUIRES)
AC_SUBST(BERYL_REQUIRES)
PKG_CHECK_MODULES(GLIB, "glib-2.0")

AC_ARG_ENABLE(gconf, [  --disable-gconf     Disable GConf backend for libberylsettings],
           [beryl_gconf=$enableval],[beryl_gconf=yes])

if test "x$beryl_gconf" = "xyes"
then
   PKG_CHECK_MODULES(GCONF, "gconf-2.0", [], [beryl_gconf=no])
fi

AM_CONDITIONAL(GCONF_BACKEND, test "x$beryl_gconf" = "xyes")
if test "$beryl_gconf" = yes; then
   AC_DEFINE(USE_GCONF, 1, [Build gconf backend])
fi

AC_ARG_ENABLE(xgl, [  --enable-xgl       Enable building of beryl-xgl],
           [beryl_xgl=$enableval],[beryl_xgl=no])

AM_CONDITIONAL(BUILD_BERYL_XGL, test "x$beryl_xgl" = "xyes")
if test "$beryl_xgl" = yes; then
   AC_DEFINE(USE_XGL, 1, [Build beryl-xgl])
fi

AC_ARG_WITH(berylmesadir,
      [  --with-berylmesadir    Set beryl internal mesa path (needed for static linked beryl-xgl) [default=../beryl-mesa] ],
      [beryl_mesa_dir=${withval}],[beryl_mesa_dir="../beryl-mesa"])


echo ""
echo "Build beryl-xgl     : $beryl_xgl"
echo "Build gconf backend : $beryl_gconf"
if ! test -f "$beryl_mesa_dir/src/Makefile" && test "x$beryl_xgl" = "xyes"; then
   AC_MSG_ERROR([The mesa dir does not exist, cannot build])

elif test "x$beryl_xgl" = "xyes"; then
   pushd $beryl_mesa_dir > /dev/null
   beryl_mesa_dir=`pwd`
   popd >/dev/null
   echo "Beryl Mesa sources: x$beryl_mesa_dir"
   AC_SUBST(beryl_mesa_dir)
fi
echo ""

AC_CONFIG_FILES([
beryl.pc
berylsettings.pc
Makefile
src/Makefile
include/Makefile
images/Makefile
doc/Makefile
libberylsettings/Makefile
settings-backends/Makefile
libberyldecoration/Makefile
libberyldecoration/libberyldecoration.pc
po/Makefile.in
])

AC_OUTPUT