on *:input:@RunescapeStats:{ if ($2) { dline @RunescapeStats 2- | aline -h @RunescapeStats Type  your  desired  username  to  lookup  in  the  window  bar | halt }
  elseif (!$2) { dline @RunescapeStats 2- | hadd -m $+(Rs.,$ticks) user $replace($1-,$chr(32),$chr(95)) | sockopen $+(Rs.,$ticks) hiscore.runescape.com 80 }
}
alias rs { if (!$window(@RunescapeStats)) { window -ek0l +bs @RunescapeStats -1 -1 * * | aline -h @RunescapeStats $chr(2) $+ Skill $chr(9) Rank $chr(9) level $chr(9) Exp }
  dline @RunescapeStats 2- | hadd -m $+(Rs.,$ticks) user $replace($1-,$chr(32),$chr(95)) | sockopen $+(Rs.,$ticks) hiscore.runescape.com 80
}
on *:SOCKOPEN:Rs.*: { 
  sockwrite -n $sockname GET /lang/en/aff/runescape/hiscorepersonal.ws?user1= $+ $hget($+(Rs.,$gettok($sockname,2,46)),user) HTTP/1.0
  sockwrite -n $sockname Host: hiscore.runescape.com $+ $str($crlf,2)
}
on *:SOCKREAD:Rs.*: { if ($sockerr) { echo -a Error - $sockname - $sockerr | halt }
  sockread &source | bwrite $sockname -1 -1 &source
  if ($bfind(&source,1,does not feature in the hiscores).text) { aline -h @RunescapeStats $hget($+(Rs.,$gettok($sockname,2,46)),user) did not feature in highscores for any skill | remove $sockname | sockclose $sockname | halt }
  if ($bfind(&source,1,No User Entered).text) { aline -h @RunescapeStats No user specified | remove $sockname | sockclose $sockname | halt }
  bread $sockname 1 $file($sockname).size $+(&,$sockname)
  var %stat, %x = 1
  while (%x) { var %x = $bfind($+(&,$sockname),$calc(%x + 1),<a href="overall.ws?table=).text, %stat = $htmlfree($bvar($+(&,$sockname),%x,200).text)
    tokenize 10 %stat
    hadd -m $sockname $1 $2 $3 $4 
  }
  if ($bfind($+(&,$sockname),1,<img class="mainscroll-bottom).text) { var %y = 0
    while (%y <= 23) { tokenize 32 $hget($sockname,$setskill(%y))
      if ($2) aline -h @RunescapeStats $setskill(%y) $chr(9) $1 $chr(9) $2 $chr(9) $3
      inc %y
    }
    sockclose $sockname | remove $sockname
  }
}
alias -l htmlfree { var %x,%y = $regsub($1-,/(<[^>]+>)/g,$null,%x) | return %x }
alias -l setskill {
  if ($1 == 0) || ($regex($1,/^(st|(skill)?total|overall)$/Si)) return Overall
  elseif ($1 == 1) || ($regex($1,/^at(t|k|tack)$/Si)) return Attack
  elseif ($1 == 2) || ($regex($1,/^def(en[cs]e)?$$/Si)) return Defence
  elseif ($1 == 3) || ($regex($1,/^str(ength)?$/Si)) return Strength
  elseif ($1 == 4) || ($regex($1,/^hp|hit(s|points?)?$/Si)) return Hitpoints
  elseif ($1 == 5) || ($regex($1,/^range(r|d|ing)?$/Si)) return Ranged
  elseif ($1 == 6) || ($regex($1,/^Pray(er)?$$/Si)) return Prayer
  elseif ($1 == 7) || ($regex($1,/^mag(e|ic)$$/Si)) return Magic
  elseif ($1 == 8) || ($regex($1,/^cook(ing)?$/Si)) return Cooking
  elseif ($1 == 9) || ($regex($1,/^wc|wood(cut(ting)?)?$/Si)) return Woodcutting
  elseif ($1 == 10) || ($regex($1,/^fletch(ing)?$/Si)) return Fletching
  elseif ($1 == 11) || ($regex($1,/^fish(ing)?$/Si)) return Fishing
  elseif ($1 == 12) || ($regex($1,/^(fire|fm)(make?(ing)?|ing)?$/Si)) return Firemaking
  elseif ($1 == 13) || ($regex($1,/^craft(ing)?$/Si)) return Crafting
  elseif ($1 == 14) || ($regex($1,/^(smith|smelt)(ing)?$/Si)) return Smithing
  elseif ($1 == 15) || ($regex($1,/^mine(ing)?$/Si)) return Mining
  elseif ($1 == 16) || ($regex($1,/^herb(law|lore)?$/Si)) return Herblore
  elseif ($1 == 17) || ($regex($1,/^agil(ity)?$/Si)) return Agility
  elseif ($1 == 18) || ($regex($1,/^(th(ei|ie)[fv](e|ing)?)$/Si)) return Thieving
  elseif ($1 == 19) || ($regex($1,/^slay(er|ing)?$/Si)) return Slayer
  elseif ($1 == 20) || ($regex($1,/^farm(er|ing)?$/Si)) return Farming
  elseif ($1 == 21) || ($regex($1,/^(rc|runecraft)(er|ing)?$/Si)) return Runecraft
  elseif ($1 == 22) || ($regex($1,/^(hunt)(er|ing)?$/si)) return Hunter
  elseif ($1 == 23) || ($regex($1,/^(con)(struc?tion)?$/si)) return Construction
}