menu * {
  $iif($group(#whois) == on,disable,enable) Custom Whois: {
    var %status = $iif($group(#whois) == on,Disable,Enable)
    $+(.,%status) #whois
    echo -ta » Custom whois has been $+(%status,d)
  }
}
alias whoisnumerics return 301|307|310|311|312|313|314|317|318|319|320|330|335|338|369|378|379|401|406|671
#whois on
raw *:*: { 
  if ($istok($whoisnumerics,$numeric,124)) haltdef
  if ($numeric == 301) echo -a » $2 is Away: $3-
  elseif ($numeric == 307) echo -a » $2 has identified for this nick.
  elseif ($numeric == 310) echo -a » $2  $+ $3-
  elseif ($numeric == 311) {
    echo -a » Whois start on $network $+ .
    /set %whoisnick $2 
    /set %whoisrealname $6-
    /set %whoishost $3 $+ @ $+ $4 
    echo -a » %whoisnick is " $+ %whoisrealname $+ " · ( $+ %whoishost $+ )
  }
  elseif ($numeric == 312) echo -a » $2 is using the server $3 - $4- 
  elseif ($numeric == 313) echo -a » $2 is a $5-9
  elseif ($numeric == 314) {
    echo -a » Whowas on $network $+ . 
    /set %whoisnick $2 
    /set %whoisrealname $6-
    /set %whoishost $3 $+ @ $+ $4 
    echo -a » %whoisnick is " $+ %whoisrealname $+ " · ( $+ %whoishost $+ )
  }
  elseif ($numeric == 317) { 
    echo -a » $2 has been idle for $duration($3) 
    echo -a » $2 signed on $duration($calc($ctime - $4)) ago
  }
  elseif ($numeric == 318) echo -a » Whois end on $network $+ .
  elseif ($numeric == 319) echo -a » $2 is on the channels: $3-
  elseif ($numeric == 320) echo -a » $2- (Swhois) 
  elseif ($numeric == 330) echo -a » Authname: $3 
  elseif ($numeric == 335) echo -a » $2 is marked as a bot on $network $+ .
  elseif ($numeric == 338) {
    echo -a » Real Hostmask: $3 
    echo -a » Real IP: $4 
  }
  elseif ($numeric == 369) echo -a » Whowas on $network $+ .
  elseif ($numeric == 378) echo -a » $2 is connecting from: $6-  
  elseif ($numeric == 379) echo -a » $2 is using the modes: $6-
  elseif ($numeric == 401) echo -a » $2 is currently not online.
  elseif ($numeric == 406) echo -a » $2 has recently not been online.
  elseif ($numeric == 671) echo -a » $2 is using a Secure Connection
} 
#whois end