alias Mp3-Player { 
  dialog -md Mp3-Player Mp3-Player
} 
menu * { 
  Mp3-Player:/dialog -md Mp3-Player Mp3-Player
}
dialog Mp3-Player {
  title "Mp3 Player by DoucheBag aka Ze Smelly Swede"
  size -1 -1 250 200
  option dbu
  list 2, 93 75 18 10
  button "Stop", 3, 90 25 20 20
  button "+", 4, 93 55 18 10
  button "-", 5, 93 65 18 10
  check "Mute", 6, 115 5 20 15
  check "Pause", 7, 115 20 30 20
  menu "File", 8
  item "Find Songs", 9, 8
  list 10, 5 5 80 70
  item "Exit", 12, 8, Cancel
  button "Play", 13, 90 5 20 20
  box "Volume", 14, 90 47 24 40
  edit "", 15, 5 80 70 10
  button "Fast Search+Play", 16, 13 70 48 10
  list 17, 150 100 80 70
  edit "", 18, 155 175 70 10
  button "Play Search", 19, 90 175 30 20
  button "Search", 20, 130 175 20 20
  button "Clear", 21, 130 150 20 20
}
on *:dialog:Mp3-Player:init:0: {
  noop $findfile($readini(mp3player.ini,directory,Playlist1),*.mp3,0,did -a mp3-player 10 $nopath($left($1-,-4)))
  did -ra Mp3-Player 2 $ceil($calc($vol(song) / 655.35))
  if ($insong == $true) {
    echo -a 12[13Currently playing $sound($insong.fname).title by $sound($insong.fname).artist $+ 12]
  }
}
on *:dialog:Mp3-Player:sclick:3: {
  splay -p stop
  did -r Mp3-Player 2
}
on *:dialog:Mp3-Player:sclick:4: {
  vol -p $calc($vol(song) + 6553.5)
  did -ra Mp3-Player 2 $ceil($calc($vol(song) / 655.35))
}
on *:dialog:Mp3-Player:sclick:5: {
  vol -p $calc($vol(song) - 6553.5)
  did -ra Mp3-Player 2 $ceil($calc($vol(song) / 655.35))
}
on *:dialog:Mp3-Player:sclick:6: {
  if (!$did($dname,6).state) vol -pu2 $vol(song)
  if ($did($dname,6).state) vol -pu1 $vol(song)
}
on *:dialog:Mp3-Player:sclick:7: {
  if ($did($dname,7).state) splay -p pause | if ($did($dname,7).state) did -ra Mp3-Player 7 Resume | if (!$did($dname,7).state) splay -p resume | if (!$did($dname,7).state) did -ra Mp3-Player 7 Pause
}
on *:dialog:Mp3-Player:menu:9: {
  did -r mp3-player 10
  .writeini mp3player.ini Directory Playlist1 $sdir(*,Select your music folder)
  noop $findfile($readini(mp3player.ini,directory,Playlist1),*.mp3,0,did -a mp3-player 10 $nopath($left($1-,-4)))
}
on *:dialog:Mp3-Player:sclick:13: { 
  if (!$did(10).seltext) {
    halt
  }
  else {
    splay -p $qt($findfile($readini(mp3player.ini,Directory,Playlist1),$+(*,$did(10).seltext,.mp3),1,))
    did -ra Mp3-Player 2 $ceil($calc($vol(song) / 655.35))
    echo -a 12[13Currently playing $sound($insong.fname).title by $sound($insong.fname).artist $+ 12]
  }
}
on *:dialog:Mp3-Player:sclick:16: { 
  if (!$did(15).text) {
    halt
  }
  else {
    splay -p $qt($findfile($readini(mp3player.ini,Directory,Playlist1),$+(*,$did(15).text,*,.mp3),1,))
    did -ra Mp3-Player 2 $ceil($calc($vol(song) / 655.35))
    did -r Mp3-Player 15
    echo -a 12[13Currently playing $sound($insong.fname).title by $sound($insong.fname).artist $+ 12]
  }
}
on *:dialog:Mp3-Player:sclick:20: { 
  noop $findfile($readini(mp3player.ini,directory,Playlist1),$+(*,$did(18).text,*,.mp3),0,did -a mp3-player 17 $nopath($left($1-,-4)))
  did -ra Mp3-Player 2 $ceil($calc($vol(song) / 655.35))
}
on *:dialog:Mp3-Player:sclick:21: { 
  did -r Mp3-Player 17
} 
on *:dialog:Mp3-Player:sclick:19: { 
  if (!$did(17).seltext) {
    halt
  }
  else {
    splay -p $qt($findfile($readini(mp3player.ini,Directory,Playlist1),$+(*,$did(17).seltext,*,.mp3),1,))
    did -ra Mp3-Player 2 $ceil($calc($vol(song) / 655.35))
    did -r Mp3-Player 18
    echo -a 12[13Currently playing $sound($insong.fname).title by $sound($insong.fname).artist $+ 12]
  }
}