on *:JOIN:#:{
  if (!$($+(%,greet.status.,$chan),2)) && ($nick == $me) set $+(%,greet.status.,$chan) on
  elseif ($($+(%,greet.status.,$chan),2) == on) && ($greet($nick)) msg $chan $+([,$nick,]) $greet($nick)
}
on $*:TEXT:/^[!.]setgreet( .+)?$/Si:#:{
  if (!$2) && ($greet($nick)) {
    rem.greet $nick
    .notice $nick Your greet has been unset.
  }
  elseif ($2) {
    add.greet $nick $2-
    .notice $nick Your greet has been set to: $2-
  }
}
on $*:TEXT:/^[!.]greet$/Si:#:{
  if ($greet($nick)) .notice $nick Your greet is currently set to: $v1
  else .notice $nick You do not currently have a greet set.
}
on $*:TEXT:/^[!.]greets( (on|off))?$/Si:#:{
  if (!$2) .notice $nick Greets are currently turned $($+(%,greet.status.,$chan),2) in $chan
  elseif ($nick($chan,$nick,ho)) {
    if ($2 == $($+(%,greet.status.,$chan),2)) .notice $nick Greets are already turned $2 in $chan
    else {
      set $+(%,greet.status.,$chan) $2
      .notice $nick Greets are now turned $2 in $chan
    }
  }
}     
alias -l greet { return $readini(Greets.ini,n,Greets,$1) }
alias -l rem.greet { remini Greets.ini Greets $1 }
alias -l add.greet { writeini Greets.ini Greets $1- }