XMLNode.prototype.moveBefore = function(beforeNode){
	if (this == beforeNode) return (0);
	beforeNode.parentNode.insertBefore( this.cloneNode(true), beforeNode);
	this.removeNode();
}
Clamp = function(min, n, max){
	if (n<min) return min;
	if (n>max) return max;
	return n;
}



var song_spacing = 20;
var over_node;
GenerateSongListing = function(playlist_xml, target_mc){
	
	target_mc = target_mc.createEmptyMovieClip("list_mc",1);
	
	var songs = playlist_xml.firstChild.childNodes;
	for (var i=0; i<songs.length; i++){
		var song_mc = target_mc.attachMovie("song", "song"+i, i);
		song_mc._y = i*song_spacing;
		
		song_mc.node = songs[i];
		song_mc.title_txt.text = songs[i].attributes.title + " - " + songs[i].attributes.artist;
		song_mc.moved = false;
		
		song_mc.select_btn.onPress = function(){
			this._parent.onMouseMove = function(){
				if (!this.moved){
					dragline_mc._visible = true;
					dragline_mc._y = playlist_mc._y + this._y;
					highlight_mc._visible = true;
					highlight_mc._y = playlist_mc._y + this._y;
					this.moved = true;
				}
			}
		}
		
		song_mc.select_btn.onDragOver = function(){
			over_node = this._parent.node;
			dragline_mc._y = playlist_mc._y + this._parent._y;
		}
		
		song_mc.onMouseUp = function(){
			if (this.onMouseMove){
				delete this.onMouseMove;
				dragline_mc._visible = false;
				highlight_mc._visible = false;
				if (this.moved){
					this.node.moveBefore(over_node);
					GenerateSongListing(playlist_xml, playlist_mc);
				}
			}
		}
		
		song_mc.select_btn.onRelease = function(){
			if (!this._parent.moved){
				SetSong(this._parent.node);
			}
		}
		
	}
}

var playlist_xml = new XML();
playlist_xml.ignoreWhite = true;
playlist_xml.onLoad = function(success){
	xmlNode = this.firstChild;
	if (success){
		GenerateSongListing(this, playlist_mc);
	}else trace("Error loading XML file"); // no success?  trace error (wont be seen on web)
	SetSong(xmlNode.childNodes[0]); //Auto load first song
}
playlist_xml.load("http://www.eskalix.com/player/mp3_playlist.xml");

dragline_mc._visible = false;
highlight_mc._visible = false;
show_mc._visible = false;