///////////////////////////////////////////////////////////
// ArmA - fNetTx.sqf by Sickboy (sb_at_6thSense.eu)
// Input - Array: [0(server) or 1(all clients) or 2(server+all clients),"string to execute",unitToExecuteOn]
// If you leave the 3rd parameter away, the execute will be done on a new gamelogic
// Output - Only in debug it will output a globalchat
///////////////////////////////////////////////////////////
	private ["_c","_t","_oc","_o"];
	_t = _this select 0;
	_c = _this select 1;
	_oc=false;
	if(count _this>2)then{_o=_this select 2;}else{_o="LOGIC" createVehicle [0,0];_oc=true;};
	if((format["%1",_c]!=six_nil)&&(_t>=0)&&(_t<= 2)) then
	{
		if(SIX_DEBUG_lvl>1&&six_isClient)then{player globalChat format["NS-Lite TX (Alt): on %3: %1, Sent to: %2",_c,_t,_o];};
		_o setVehicleInit format["if(!(isNil 'SIX_Misc_Init'))then{[this,%1,""%2""] call six_fNetRx};",_t,_c];
		processInitCommands;
		if(_oc)then{_o spawn {sleep 5;deleteVehicle _this};};
	}else{
		if(SIX_DEBUG_lvl>1&&six_isClient)then{player globalChat "NS-Lite TX (Alt): Function Executing failed, invalid string or destination";};
	};




///////////////////////////////////////////////////////////
// ArmA - fNetRx.sqf by Sickboy (sb_at_6thSense.eu)
///////////////////////////////////////////////////////////
private ["_c","_t","_o"];
_o=_this select 0; // Unit
_t=_this select 1; // Type
_c=_this select 2; // Command

switch _t do
{
	case 0: {if(six_isServer)then{if(SIX_DEBUG_lvl>1&&six_isClient)then{player globalChat format["NS-Lite RX (Alt): on %3: %1, Sent to: %2: %1",_c,_t,_o];};_o call compile _c;};};
	case 1: {if(six_isClient)then{if(SIX_DEBUG_lvl>1&&six_isClient)then{player globalChat format["NS-Lite RX (Alt): on %3: %1, Sent to: %2: %1",_c,_t,_o];};_o call compile _c;};};
	case 2: {if(SIX_DEBUG_lvl>1&&six_isClient)then{player globalChat format["NS-Lite RX (Alt): on %3: %1, Sent to: %2",_c,_t,_o];};_o call compile _c;};
};