# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit gnome2 autotools git

EGIT_REPO_URI="git://anongit.freedesktop.org/git/xorg/app/compiz"

DESCRIPTION="3D composite- and windowmanager"
HOMEPAGE="http://www.compiz.org/"
SRC_URI=""

LICENSE="GPL-2 LGPL-2.1 MIT"
SLOT="0"
KEYWORDS=""
IUSE="dbus fuse gnome gtk kde svg" 

DEPEND=">=media-libs/mesa-6.5.1-r1
	>=media-libs/glitz-0.5.6
	>=x11-base/xorg-server-1.1.1-r1
	x11-libs/libXdamage
	x11-libs/libXrandr
	x11-libs/libXcomposite
	x11-libs/libXinerama
	x11-proto/damageproto
	media-libs/libpng
	>=x11-libs/gtk+-2.8.0
	x11-libs/startup-notification
	gnome? ( gnome-base/gconf
		>=x11-libs/libwnck-2.16.1
		>=gnome-base/control-center-2.16.1 )
	svg? ( gnome-base/librsvg )
	dbus? ( >=sys-apps/dbus-1.0 )
	kde? (
		|| ( kde-base/kwin kde-base/kdebase )
		dev-libs/dbus-qt3-old )
	fuse? ( sys-fs/fuse )"

RDEPEND="${DEPEND}
	x11-apps/mesa-progs"

pkg_setup() {
	if use gnome && ! use gtk ; then
		echo
		eerror "In order to compile compiz with gnome support"
		eerror "it needs to be built with the 'gtk' USE flag"
		eerror "set as well."
		die "GNOME support requires GTK support."
	fi
}

src_compile() {
	eautoreconf || die "eautoreconf failed"
	intltoolize --copy --force || die "intltoolize failed"
	glib-gettextize --copy --force || die "glib-gettextize failed"

	econf \
		--with-default-plugins \
		$(use_enable gtk) \
		$(use_enable gnome gconf) \
		$(use_enable gnome) \
		$(use_enable gnome metacity) \
		$(use_enable kde) \
		$(use_enable svg librsvg) \
		$(use_enable dbus) \
		$(use_enable dbus dbus-glib) \
		$(use_enable fuse) || die "econf failed"

	emake || die "emake failed"
}

src_install() {
	emake DESTDIR="${D}" install || die "emake install failed"
	dodoc AUTHORS NEWS README TODO

	# Install a .desktop file for starting a GNOME/Compiz session. This file,
	# as well as its compiz-gnome-session helper file, is based on Openbox'
	# session scripts (http://icculus.org/openbox).
	dobin ${FILESDIR}/${PN}-gnome-session

	dodir /usr/share/xsessions
	insinto /usr/share/xsessions
	doins ${FILESDIR}/${PN}-gnome.desktop
}