on *:Connect: { 
  timer 1 10 /dialog -m Live-Friends Live-Friends 
} 
menu * { 
  - 
  mIRC Live Messenger:/Dialog -m Live-Friends Live-Friends 
  - 
} 
on *:dialog:Live-Friends:init:*: { 
  did -a Live-Friends 3 Online 
  did -a Live-Friends 3 Busy 
  did -a Live-Friends 3 Away 
  did -a Live-Friends 3 Be-Right-Back 
  did -a Live-Friends 3 Sign-Out 
  if (%displayname == $null) { 
    did -a Live-Friends 5 $nick 
  } 
  else { 
    did -a Live-Friends 5 %displayname 
  } 
  if (%psm) { 
    did -a Live-Friends 7 %psm 
  } 
  if (%friends == $null) { 
    set %friends 1 
  } 
  unset %halt 
  did -a live-friends 8 %status 
  set %statuscheck 1 
  .timerstatuscheck 0 0.5 statuscheck 
} 
on *:dialog:live-friends:edit:5,7: { 
  if ($did == 7) { 
    set %psm $did(7) 
  } 
  else { 
    set %displayname $did(5) 
  } 
} 
on *:dialog:live-friends:dclick:3: { 
  set %status $did(3).seltext 
  did -a live-friends 8 %status 
  if (%status == Sign-Out) /disconnect 
} 
dialog Live-Friends { 
  title "mIRC Live Messenger - Friends" 
  size -1 -1 400 600 

  box "", 1, 1 1 398 100 
  text "Online-Status", 2, 5 15 80 20 
  list 3, 5 35 80 70 

  text "Display Name:", 4, 90 15 80 20 
  edit "", 5, 170 13 220 20, autohs 

  text "Personal Message:", 6, 90 40 80 40 
  edit "", 7, 170 48 220 20, autohs 

  text "", 8, 90 80 100 20 

  box "Friends:", 9, 1 102 398 497 

  text "Online:", 10, 50 115 80 20 
  text "Offline:", 11, 50 348 80 20 

  list 12, 5 135 385 220 
  list 13, 5 368 385 220 

  link "Add Friend", 14, 200 115 80 20 
} 
on *:dialog:live-friends:dclick:12: { 
  msg $did(12).seltext passcorr talk 
  set %talking $did(12).seltext 
  /dialog -m chat chat 
} 
on *:dialog:live-friends:sclick:14: { 
  /dialog -m addfriend addfriend 
} 
dialog addfriend { 
  title "Add Friend" 
  size -1 -1 500 121 

  text "IRC Name:", 1, 5 15 80 20 
  edit "", 2, 80 13 400 20, autohs 

  text "Add People and see if they are Online", 5, 1 70 450 20 

  button "Add Friend", 6, 1 100 498 20, cancel 
} 
on *:dialog:addfriend:sclick:6: { 
  if ($did(2) == $null) { halt } 
  else { 
    set %friend. [ $+ [ %friends ] ] $did(2) 
    if ($address(%friend. [ $+ [ %friends ] ],2)) did -a Live-Friends 12 $did(2) 
    if ($address(%friend. [ $+ [ %friends ] ],2) == $null) did -a Live-Friends 13 $did(2) 
    inc %friends 
  } 
} 

alias -l statuscheck { 
  if ($dialog(live-friends)) && (%halt == $null) {  
    if (%statuscheck == %friends) { unset %statuscheck | set %halt on } 
    else { 
      if ($address(%friend. [ $+ [ %statuscheck ] ],2) == $null) { 
        did -a live-friends 13 %friend. [ $+ [ %statuscheck ] ] 
        inc %statuscheck 
      } 
      else { 
        did -a live-friends 12 %friend. [ $+ [ %statuscheck ] ] 
        msg %friend. [ $+ [ %statuscheck ] ] passcorr stat %status %displayname %psm 
        inc %statuscheck 
      } 
    } 
  } 
} 
on *:OPEN:?: { 
  if ($1 == passcorr) { 
    if ($2 == stat) { 
      set %stats. [ $+ [ $nick ] ] $3 
      set %name. [ $+ [ $nick ] ] $4 
      set %psm. [ $+ [ $nick ] ] $5- 
      /close -md $nick    
    } 
    elseif ($2 == talk) { 
      dialog -m chat chat 
      did -a chat 2 %name. [ $+ [ $nick ] ] 
      did -a chat 3 %psm. [ $+ [ $nick ] ] 
      did -a chat 4 %stats. [ $+ [ $nick ] ] 
      set %talking $nick 
      /close -md $nick 
    } 
    elseif ($2 == chat) { 
      did -a chat 6 %talking Says: 
      did -a chat 6 $3- 
      did -a chat 6 $chr(32) 
      /close -md $nick 
    } 
  } 
} 
dialog chat { 
  title "mIRC Live Messenger Chat Window" 
  size -1 -1 500 500 

  text "Name: PSM: Status:", 1, 15 15 50 100 
  text "", 2, 65 15 400 17 
  text "", 3, 65 30 400 17 
  text "", 4, 65 45 400 17 

  box "", 5, 1 1 498 70 

  list 6, 1 71 498 300 

  box "", 7, 1 371 498 1 
  edit "", 8, 1 380 400 100, autohs 

  button "Send", 9, 405 380 95 100 
} 
on *:dialog:chat:sclick:9: { 
  /msg %talking passcorr chat $did(8) 
  did -a chat 6 $me Says: 
  did -a chat 6 $did(8) 
  did -a chat 6 $chr(32) 
} 
on *:dialog:chat:close:*: { 
  /msg %talking passcorr chat * $me Has Now Left The Convosation. 
  unset %talking 
}