alias gban { 
  if (*!*@* iswm $1) var %m = $1 
  elseif ($comchan($1,0) > 0) var %m = $address($1,2), %n = $1 
  else { 
    .enable #gban 
    if ($2) set %gban.reason $2- 
    userhost $1 
    halt 
  } 
  var %a = $chan(0), %b = 1, %message = $iif(%n,Globally banning %n $+($chr(40),%m,$chr(41)) $iif($2,for reason: $2-),Globally banning $qt(%m) $iif($2,for reason: $2-)) 
  while (%b <= %a) { 
    var %c = $chan(%b) 
    if ($nick(%c,$me,ho)) { 
      msg %c %message 
      mode %c +b %m 
    } 
    inc %b 
  } 
} 
#gban off
raw 302:*:{ 
  if (!$2) { 
    echo 4 -a * /gban: no such nick 
  } 
  else { 
    var %m = $+(*!*@,$gettok($2,2,$asc(@))), %n = $gettok($2,1,$asc(=)) 
    var %a = $chan(0), %b = 1 
    while (%b <= %a) { 
      var %c = $chan(%b) 
      if ($nick(%c,$me,ho)) { 
        msg %c Globally banning %n $+($chr(40),%m,$chr(41)) $iif(%gban.reason,for reason: $v1) 
        mode %c +b %m 
      } 
      inc %b 
    } 
  } 
  if (%gban.reason) unset %gban.reason 
  .disable #gban 
} 
#gban end