on *:load:{
  /set %awaypage on
  /set %awayidle on
  /set %idletime.min 15
  /set %idletime.sec 900
  /set %awaymemo off
  /set %away.silent off
  /set %awaynick.use off
  /set %awaynick tk-away
}

on *:connect:{
  //.join -n #botevci
  if (%awayidle == on) { //.timerchkidle 0 5 /checkidle }
}
alias awayon {
  /unset %awayuser.*
  /dialog -m xaway xaway
}
alias awayoff {
  if ( $away == $true ) {
    if (%awaynick.use == on) { /nick %awaynick.old }
    /resetidle 0
    /away 
    if (%away.silent != on) { /ame is back.4>>> He was gone for $duration($calc($ctime - %aw.time)) 4<<< }
    /set %way off  
    /titlebar Watch The Skies
  }
  else { /echo -a $ud 4>>> You Are Not Away!! 4<<< $ud }
}
on *:text:*:#:{
  if ( $me isin $1- ) { 
    if ( $away == $true ) { 
      if (%awaylog == on) { 
        /window @AwayLog
        /echo @awaylog 8[12 $+ $time $+ 8]4 < $+ $chan $+ / $+ $nick $+ >11 $1-
      }
      if ( %awayuser. $+ $nick !== yes ) { 
        /.msg $chan >>> I`m Gone: ( %away.reason ) - from  $+ $duration($calc($ctime - %aw.time)) 4<<<
        /set %awayuser. $+ $nick yes 
      } 
    }
  }
}

on *:text:*:?: { 
  if ($away == $true) { 
    /.notice $nick >>> I`m gone: ( %away.reason ) - from  $+ $duration($calc($ctime - %aw.time)) 4<<<
    if ( %awaypage == on ) { /.notice $nick >>> Type /ctcp $me page to get my attention back on the computer if I`m around 4<<< }
    if (%awaylog == on) { 
      /window @AwayLog
      /echo @awaylog 8[12 $+ $time $+ 8]4 < $+ $nick $+ >15 $1-
    }
  }
}
ctcp *:page:?:{
  if ($away == $true) {  
    if ( %awaypage == on ) { /dialog -m paging paging | /beep 10000 1 | /flash Away Pager! | /.notice $nick PAGING!... | /echo -s 9<+*+>4 $nick is PAGING you... }
  }
}
on *:open:?:{
  if ($away == $true) {
    if (%awaylog == on) { //.timerclose $+ $nick 1 1 /closemsg $nick }
  }
}

menu menubar,status,channel,query,nicklist {
  -<| AwAy( $+ $iif($away == $true,YES,NO) $+ )|>-
  .-
  .On:/awayon
  .Off:/awayoff
  .-
  .Settings
  ..Pager(now %awaypage $+ )
  ...ON:/set %awaypage on
  ...OFF:/set %awaypage off
  ..Idle(now %awayidle $+ )
  ...ON:/set %awayidle on
  ...OFF:/set %awayidle off
  ...-
  ...Time(now %idletime.min min):{
    /set %idletime.min $?="Enter the time in minutes:"
    /set %idletime.sec $calc(%idletime.min * 60)
  }
  ..Log(now %awaylog $+ )
  ...ON:/set %awaylog on
  ...OFF:/set %awaylog off
  ..Use Nick(now %awaynick.use $+ )
  ...ON:/set %awaynick.use on
  ...OFF:/set %awaynick.use off
  ...-
  ...Nick(now %awaynick $+ ):/set %awaynick $?="Enter your away nick:"
  ..Silent(now %away.silent $+ )
  ...ON:/set %away.silent on
  ...OFF:/set %away.silent off
}
menu @AwAyLog {
  Close:/close -@ @AwAyLog
}
dialog paging {
  title "PAGING!!!"
  size 162 250 193 35
  option dbu
  button "OK", 10, 27 17 137 11, cancel,
  text "Press the OK Button to STOP Beeping!", 20, 6 5 181 6, center,
}
on *:dialog:paging:sclick:*:{
  if ( $did == 10 ) { /beep off }
}
alias checkidle {
  if ($away == $false) {
    if ($idle >= %idletime.sec) {
      /unset %awayuser.*
      /set %away.reason Not Here Anymore...
      /away  %away.reason 
      if (%away.silent != on) { /ame is gone.>>> Reason - %away.reason (automatic after %idletime.min minutes idle) 4<<< }
      /set %way on 
      /set %aw.time $ctime
    }
  }
}
dialog xaway {
  title "Away System" 
  size -1 -1 175 52 
  option dbu
  text "&Away message:", 202, 5 7 37 7
  edit "", 1, 43 5 118 11, autohs
  text "0", 4, 163 7 13 7
  check "&Pager on", 2, 5 21 44 7 
  check "&Log on", 3, 58 21 39 7
  button "OK", 101, 5 35 27 12, OK default flat
  button "Cancel", 102, 38 35 27 12, cancel flat
  check "&Nick:", 103, 75 38 22 7
  edit "", 105, 98 36 73 11
  check "Silent", 104, 107 21 60 7
} 
on *:dialog:xaway:init:*:{
  if (%awaypage == off) { did -u xaway 2 }
  if (%awaypage == on) { did -c xaway 2 }
  if (%awaylog == off) { did -u xaway 3 }
  if (%awaylog == on) { did -c xaway 3 }
  if (%awaynick.use == off) { did -u xaway 103 }
  if (%awaynick.use == on) { did -c xaway 103 }
  if (%away.silent == off) { did -u xaway 104 }
  if (%away.silent == on) { did -c xaway 104 }
  if (%awaynick !== $null) { did -a xaway 105 %awaynick }
}
on *:dialog:xaway:sclick:*:{
  if ($did == 2) { 
    if (%awaypage == on) { /set %awaypage off }
    else { /set %awaypage on } 
  }
  if ($did == 3) { 
    if (%awaylog == on) { /set %awaylog off }
    else { /set %awaylog on } 
  }
  if ($did == 103) { 
    if (%awaynick.use == on) { /set %awaynick.use off }
    else { /set %awaynick.use on } 
  }
  if ($did == 101) { 
    /set %awaynick $did(105)
    if ($did(1) == $null) { /echo -a $ud 4Please enter away reason!!! $ud | halt }
    /set %away.reason $did(1)
    /away  %away.reason 
    if (%away.silent != on) { /ame is gone.4>>> Reason - %away.reason  4<<< }
    /set %way on 
    /set %aw.time $ctime
    /titlebar >>> AwAy: %away.reason $+ <<<
    if (%awaynick.use == on) { /set %awaynick.old $me | /nick %awaynick }
  }
  if ($did == 104) { 
    if (%away.silent == on) { /set %away.silent off }
    else { /set %away.silent on } 
  }
}

on *:DIALOG:xaway:edit:1:{ doeditboxchk }
alias -l doeditboxchk {
  if ($len($did(1)) < 100) { did -a $dname 4 $len($did(1)) }
  if ($len($did(1)) == 100) { %did1text = $did(1) | did -a $dname 4 Max }
  if ($len($did(1)) == 101) { did -ar $dname 1 %did1text | beep 1 | %did1text = $did(1) }
}