// check if all standard tags are present
$if($meta_test(title,artist,album),
// formatting for files with tags:

// check if track belongs to VA album
$if($or($stricmp(%album artist%,VA),$stricmp($left(%album artist%,7),various)),$puts(va,1),)

// 'album' formatting
$puts(album,%album%
)
$puts(tracknum,$ifgreater(%tracknumber%,0,%tracknumber% - ,))


//if 'album artist' tag is present
$if(%album artist%,
// set 'artist' to VA for VA albums, and to 'album artist' otherwise:
$if($get(va),$puts(artist,VA),$puts(artist,%album artist%))
//if 'artist' is different from 'album artist', append the former to the title
$if($strcmp(%album artist%,%artist%),$puts(title,%title%),
$puts(title,%artist% - %title%)),
//no 'album artist' found
$puts(artist,%artist%)$puts(title,%title%)
)



// formatting for files without all the tags:
,
$if(%title%,
$puts(title,%title%)$if(%artist%,$puts(artist,%artist%))$if(%album%,$puts(album,%album%)),
$puts(title,$if($stricmp($left(%_path_raw%,7),'http://'),%_path_raw%,$replace(%_filename_ext%,_, ))))
)

$num(%_playlist_number%,$len(%_playlist_total%)).' '
[$get(album) - ]
[$get(artist) - ]
[$get(tracknum)]
[$get(title)]
[$char(9)$if(%_isplaying%,'|> ')%_length%]