raw *:*:{
  if ($numeric isnum 473-475) {
    cs invite $2
  }
}

on *:invite:#:{
  join #
}

on *:devoice:#:{
  if ($vnick == $me) && ($nick != $me) && ($me !ishop # && $me !isop #) {
    cs voice #
  }
}

on *:voice:#:{
  if ($vnick == $me) && ($me ishop # || $me isop #) {
    mode # -v $me
  }
}

on *:dehelp:#:{
  if ($hnick == $me) && ($nick != $me) && ($me !isop #) {
    cs halfop #
  }
}

on *:help:#:{
  if ($hnick == $me) && ($me isop #) {
    mode # -h $me
  }
}

on *:deop:#:{
  if ($opnick == $me) && ($nick != $me) {
    cs op #
  }
}

on *:op:#:{
  if ($opnick == $me) {
    mode # -hv $me $me
  }
}

on *:kick:#:{
  if ($knick == $me) {
    join #
  }
}

on *:ban:#:{
  if ($banmask iswm $address($me,5)) || ($banmask iswm $+(~q:,$address($me,5))) || ($banmask iswm $+(~n:,$address($me,5))) || ($banmask iswm $+(~r:,$fullname)) {
    mode # -b $banmask
  }
}

on *:rawmode:#:{
  if (e isincs $1) || (I isincs $1) {
    var %x = 2
    while ($($+($,%x),2)) {
      $iif($v1 iswm $address($me,5),mode # +eI $address($me,0) $address($me,0))
      inc %x
    }
  }
}

on *:join:#:if ($nick == $me) mode # eI $address($me,2) $address($me,2)