ON *:START:{
  .color Action text 10 
  .color Ctcp text 04 
  .color Highlight text 07 
  .color Info text 07 
  .color Info2 text 07 
  .color Invite text 10 
  .color Join text 10 
  .color Kick text 10 
  .color Mode text 10 
  .color Nick text 10 
  .color Normal text 10 
  .color Notice text 07 
  .color Other text 10 
  .color Own text 10 
  .color Part text 10 
  .color Quit text 02 
  .color Topic text 03 
  .color Wallops text 04 
  .color Whois text 10 
  .color Editbox text 07 
  .color Listbox text 10 
  .color Gray text 10 
  .color Title text 10 
  .color Treebar text 10 
  .color Editbox 0 
  .color Listbox 0 
  .color Treebar 0 
  .color Inactive 0 
  .color BackGround 0 
  echo -at $T1(Welcome to mIRC) $T2($version) 
  echo -a - 
  echo -at $T1(You're using the theme:) $T2(RUSH V0.1.0) 
  echo -a - 
  echo -at $Logo 
} 
Alias T1 return $+($chr(3),5,$1-,$chr(3)) 
Alias T2 return $+($chr(3),15,$1-,$chr(3)) 
Alias T3 return $+($chr(3),02,$1-,$chr(3)) 
Alias TB1 return $+($chr(2),$chr(3),5,$1-,$chr(2),$chr(3)) 
Alias TB2 return $+($chr(2),$chr(3),15,$1-,$chr(2),$chr(3)) 
Alias Logo return $+($T1([),$T2(RUSH),$T1(])) 
Alias U return $+($chr(31),$left($1,1),$chr(31),$right($1,-1)) 
Alias NickStyle return $iif($2 !isreg $1,$+($RankColor($left($nick($1,$2).pnick,1)),$T2($U($2))),$T2($U($2))) 
Alias RankColor { 
  return $replace($1,~,$+($chr(3),04,~,$chr(3)),&,$+($chr(3),04,&,$chr(3)),@,$+($chr(3),04,@,$chr(3)),%,$+($chr(3),03,%,$chr(3)),+,$+($chr(3),02,+,$chr(3)))) 
} 
Alias AMSG { 
  var %i = 1 
  while ($chan(%i)) { 
    if ($chan(%i) != #Idle) {    
      .msg $chan(%i) $1- 
      echo -tm $chan(%i) $+($TB1($chr(40)),$NickStyle($chan(%i),$me),$TB1($chr(41))) $T1($1-) 
    } 
    inc %i 
  } 
} 
ON ^*:TEXT:*:*:{ 
  haltdef 
  echo -tm $iif($chan,$chan,$nick) $+($TB1($chr(40)),$NickStyle($chan,$nick),$TB1($chr(41))) $T1($1-) 
} 
ON ^*:ACTION:*:*:{ 
  haltdef 
  echo -tm $iif($chan,$chan,$nick) $+($NickStyle($chan,$nick)) $TB1(*) $T1($1-) 
} 
CTCP *:VERSION:{ 
  ctcpreply $nick VERSION James' Theme - RUSH V0.1.0 
} 
ON ^*:NOTICE:*:*:{ 
  haltdef 
  echo -satm $iif($chan,$chan) $+($TB1(-),$+($T2($U($nick)),$iif($chan,$+($T1(:),$T2($chan)))),$TB1(-)) $T1($1-) 
} 
ON ^*:SNOTICE:*:{ 
  haltdef 
  echo -sat $+($TB1(-),$T2($nick),$TB1(-)) $T1($1-) 
} 
ON ^*:INVITE:*:{ 
  haltdef 
  echo -astm $T2($U($nick)) $T1(has invited you to) $T2($chan) 
} 
ON ^*:TOPIC:*:{ 
  haltdef 
  echo -tm $chan $T2($U($iif($nick == $me,You,$nick))) $T1(has chanegd the topic to) $T2($1-) 
} 
ON *:CONNECT:{ 
  join #Terror 
} 
ON ^*:JOIN:*:{ 
  haltdef 
  echo -tm $chan $T2($U($nick)) $T1(has joined) $T2($chan) 
  if ($nick != $me) { 
    var %i = 0 
    while (%i < $nick($chan,0)) { 
      inc %i 
      if ($address($nick,2) iswm $address($nick($chan,%i),5)) { 
        var %users = $iif(%users,$+(%users,$chr(32),$NickStyle($chan(%i),$nick($chan,%i))),$NickStyle($chan(%i),$nick($chan,%i))) 
      } 
    } 
    $iif($strip(%users,cbu) != $nick && %users,echo -tm $chan $T1(Clones:) $T2(%users)) 
  } 
} 
ON ^*:PART:*:{ 
  haltdef 
  echo -tm $chan $T2($U($nick)) $T1(has parted) $T2($chan) $iif($1,$+($T1([),$T2($1-),$T1(]))) 
} 
ON ^*:KICK:*:{ 
  haltdef 
  echo -tm $chan $T2($U($nick)) $T1(has kicked) $T2($u($knick)) $+($T1([),$T2($1-),$T1(])) 
} 
ON ^*:RAWMODE:*:{ 
  haltdef 
  echo -tm $chan $T2 [ $+ ($U($nick) $+ ] ) $T1(has set mode $+ $iif($len($1) > 2,s) $+ :) $T1($1) $T2($2-) 
} 
Raw 332:*:{ 
  haltdef 
  echo -tm $2 $T1(Topic is) $+(',$T2($3-),') 
} 
Raw 319:*:{ 
  haltdef 
  echo -a $2 is on $replace($3-,~,$+($chr(3),04,~,$chr(3)),&,$+($chr(3),04,&,$chr(3)),@,$+($chr(3),04,@,$chr(3)),%,$+($chr(3),03,%,$chr(3)),+,$+($chr(3),02,+,$chr(3)))) 
} 
Raw 333:*:{ 
  haltdef 
  echo -tm $2 $T1(Set by) $T2($3) $T1(on) $T2($asctime($4-)) 
} 
ON *:TEXT:$(* $+ $me $+ *):#:{ 
  beep 3  
  if ($chan != $active) echo -astm $+($TB1($chr(40)),$NickStyle($chan,$nick),$T1(:),$T2($chan),$TB1($chr(41))) $T1($1-) 
} 
ON *:INPUT:*:{ 
  if ($left($1,1) == /) return 
  else { 
    .msg $active $1- 
    echo -tm $active $+($TB1($chr(40)),$NickStyle($active,$me),$TB1($chr(41))) $T1($1-) 
    halt 
  } 
}