new_3-1.gat,30,32,0	script	Cult Recruiter	103,{
	if (QUEST_Halloween07_state > 0) goto L_NextNPC;

	mes "[Cult Recruiter Dulas]";
	mes "Hello, I am Dulas, a member of a new";
	mes "cult that just arrived in the mana world.";
	mes "Our goal is to archieve ultimate power";
	mes "through summoning demons.";
	next;
	mes "[Cult Recruiter Dulas]";
	mes "We are currently searching for new";
	mes "members.";
	mes "Are you interested in joining us?";
	next;
	menu "Sure, why not.", L_Join, "No, that sound's fishy to me.", -;
	mes "[Cult Recruiter Dulas]";
	mes "Come on, don't you want to become";
	mes "more powerful? Just try it, you can";
	mes "leave anytime.";
	next;
	menu "OK, count me in.", L_Join, "Sorry, not my thing.";
	close;
	L_Join:
		if (Level < 20) goto L_Join_No;
		mes "[Cult  Recruiter Dulas]";
		mes "Splendid! You should meet another";
		mes "member of our brotherhood. Brother";
		mes "Melfar in the snow village. He will";
		mes "tell you more about us.";
		mes "I'll stay here and recruit more members";
		mes "for our cause.";
		set QUEST_Halloween07_state, 1;
		close;
	L_Join_No:
		mes "[Cult  Recruiter Dulas]";
		mes "Sorry, but you have to be at least";
		mes "level 20 to join us.";
		close;
	L_NextNPC:
		mes "[Cult  Recruiter Dulas]";
		mes "You should go and meet Melfar in the snow village.";
		close;
}

new_11-1.gat,75,85,0	script	Cult Member	103,{
	if (QUEST_Halloween07_state < 1) goto L_FirstNPC;
	if (QUEST_Halloween07_state > 1) goto L_NextNPC;
	mes "[Cult Member Melfar]";
	mes "Ah, you must be our newest member.";
	mes "Dulas told me you would come.";
	mes "So you want to know more about us?";
	next;
	mes "[Cult Member Melfar]";
	mes "We are the halloween cult.";
	mes "We practice dark rituals around the";
	mes "time of halloween to gain powerful";
	mes "artefacts.";
	next;
	mes "[Cult Member Melfar]";
	mes "We will soon accomplish a ritual";
	mes "we have been preparing the whole year.";
	mes "There are just a few more preparations";
	mes "that have to be completed.";
	set QUEST_Halloween07_state, 2;
	next;
	L_NextNPC:
	mes "[Cult Member Melfar]";
	mes "Talk to our leader Sarkor.";
	mes "He will give you a task to help";
	mes "with the preparations.";
	mes "The last time I saw him he was";
	mes "in Hurnscald, the forrest village.";
	close;

	L_FirstNPC:
		mes "[Cult Member Melfar]";
		mes "Hello, I am a member of a new cult";
		mes "that just arrived in the mana world.";
		next;
		mes "[Cult Member Melfar]";
		mes "When you want to know more about us";
		mes "you should go and see our recruiter";
		mes "Dulas in Tulimshar";
		close;

}

new_19-1.gat,52,39,0	script	Cult Leader	103,{
	if (QUEST_Halloween07_state < 2) goto L_FirstNPC;
	if (QUEST_Halloween07_state > 2) goto L_NextNPC;
	mes "[Cult Leader Sarkor]";
	mes "Ah, the newbie.";
	next;
	mes "[Cult Leader Sarkor]";
	mes "We collect powerful artefacts by";
	mes "summoning powerful demons from the";
	mes "netherworld. When we summon them we";
	mes "pretent to worship them. But when";
	mes "they appear we fight them and take";
	mes "the items they are carrying.";
	next;
	mes "[Cult Leader Sarkor]";
	mes "Around the time of halloween the";
	mes "barrier between this world and the";
	mes "netherworld is very weak.";
	mes "This will allow us to summon one of";
	mes "the lesser demons that will be easy to";
	mes "defeat.";
	next;
	mes "[Cult Leader Sarkor]";
	mes "But the demons we summon are still";
	mes "demons and thus very tough enemies.";
	mes "Taking part in our rituals is very";
	mes "dangerous. Are you sure you are";
	mes "experienced enough to face a demon?";
	next;
	menu "Sure I am",L_Mission, "Nah, might be too tough.",-;
	mes "[Cult Leader Sarkor]";
	mes "I can understand your decision.";
	mes "Maybe next year you will be strong";
	mes "enough to face a demon.";
	close;

	L_Mission:
		mes "[Cult Leader Sarkor]";
		mes "That's the spirit.";
		set QUEST_Halloween07_state, 3;
		next;
	L_NextNPC:
		mes "[Cult Leader Sarkor]";
		mes "Our preparations are almost complete.";
		mes "Go to our high priest Torgas and help";
		mes "him with his preparations. He is at a";
		mes "stone circle to the west.";
		close;
	L_FirstNPC:
        mes "[Cult Leader Sarkor]";
        mes "Hello, I am the leader of a new cult";
        mes "that just arrived in the mana world.";
        next;
        mes "[Cult Leader Sarkor]";
        mes "I am currently too busy to chat.";
        mes "When you want to know more about us";
        mes "you should go and see our recruiter";
        mes "Dulas in Tulimshar";
        close;
}

new_9-1.gat,57,41,0	script	Cult Priest	103,{
	if (QUEST_Halloween07_state < 3) goto L_FirstNPC;
	if (QUEST_Halloween07_state == 4) goto L_Deliver;
	if (QUEST_Halloween07_state == 5) goto L_Summon;
	if (QUEST_Halloween07_state == 6) goto L_End;

    mes "[Cult Priest Torgas]";
    mes "(mumbling some words you";
    mes "don't understand.)";
    next;
    menu "Sarkor sent me to help you.", -, "(leave him alone)", close;
    mes "[Cult Priest Torgas]";
    mes "(stops mubling)";
    mes "Ah, good.";
    next;
    mes "[Cult Priest Torgas]";
    mes "The ritual is almost finished.";
    mes "I contacted a strong demon in";
    mes "the netherworld.";
    next;
    mes "[Cult Priest Torgas]";
    mes "All we need to break the barrier";
    mes "are a few dark crystals. 5 should";
    mes "be enough. Would you get those for";
    mes "me?";
    next;
    menu "Sure, but how?",-;
    mes "[Cult Priest Torgas]";
    mes "During the time of halloween some";
    mes "lesser demons roam the mana world.";
    mes "They appear in the shape of floating";
    mes "skulls. Maybe you have already seen";
    mes "some of them.";
    next;
    mes "[Cult Priest Torgas]";
    mes "Sometimes they carry dark crystals.";
    mes "with them. Go and hunt them.";
    set QUEST_Halloween07_state, 4;
    close;

	L_Deliver:
		mes "[Cult Priest Torgas]";
		mes "have you got the 5 crystals?";
		next;
		if (countitem(631) < 5) goto L_Deliver_Notenough;
		menu "Not yet.",close,"Here they are.",-;
		delitem 631,5;
		set QUEST_Halloween07_state, 5;
		mes "[Cult Priest Torgas]";
		mes "Good. Very good. My preparations are";
		mes "finished, too. We can start anytime.";
		mes "But before we start you should know";
		mes "that the demon you are about to face";
		mes "is the strongest creature you have ever";
		mes "fought. It is stronger than any other";
		mes "creature living in this world.";
		next;
		mes "Before you fight it you should make";
		mes "some preparations and maybe get some";
		mes "friends to help you.";
		mes "come back when your preparations are completed.";
		close;

	L_Deliver_Notenough:
		menu "Not yet.",-;
		mes "[Cult Priest Torgas]";
		mes "Then what are you doing here?";
		mes "Go and hunt some of the floating";
		mes "skulls!";
		close;

	L_Summon:
		mes "[Cult Priest Torgas]";
		mes "Have you completed your preparations?";
		mes "Are you sure you can face the demon?";
		next;
		menu "No, I need a bit more time.",close,"Yes, go and summon it.",-;
		mes "OK, here it comes. Get ready!";
		next;
		set QUEST_Halloween07_state, 6;
		monster "new_9-1.gat",57,42, "Halloween Demon",1022,1;
		gmcommand strcharinfo(0)+":@spawn 1020 1 ";
		close;

	L_End:
		mes "[Cult Priest Torgas]";
		mes "Is the demon defeated?";
		mes "I hope it dropped some valuable";
		mes "artefacts.";
		mes "";
		mes "See you again next halloween.";
		close;

	L_FirstNPC:
		mes "[Cult Priest Torgas]";
        mes "(mumbling some words you";
        mes "don't understand.)";
        next;
        menu "Err... hello?", -, "(leave him alone)", L_Close;
        mes "[Cult Priest Torgas]";
        mes "Go away!";
		next;
		menu "What are you doing here?",-,"(go away)", L_Close;
		mes "[Cult Priest Torgas]";
		mes "Can't you see that I am busy?";
		mes "Go to Dulas in Tulimshar when you";
		mes "want to know more about us.";
        close;

   	L_Close:
		close;
}