echo == u-boot settings ==
setenv baudrate 115200
setenv bootcmd run bootflash
setenv bootdelay 2
setenv loads_echo 1
setenv stdin serial
setenv stdout serial
setenv stderr serial
echo == network settings ==
setenv ethaddr 00:04:9f:ef:03:01
setenv eth1addr 00:04:9f:ef:03:02
setenv gatewayip 192.168.95.1
setenv netmask 255.255.255.0
setenv ipaddr 192.168.95.254
setenv serverip 192.168.95.230
echo == memory addresses ==
setenv loadaddr 200000
setenv loadkernaddr 200000
setenv loadfdtaddr 400000
setenv ubootaddr fe000000
setenv fdtaddr fe080000
setenv kernaddr fe100000
setenv kernsize 200000
setenv rootaddr fe300000
setenv rootsize d00000
echo == file names ==
setenv tftproot mpc8323e-rdb
setenv setargs 'setenv ethact; setenv ubootfile $tftproot/u-boot.bin; setenv envfile $tftproot/u-boot.env; setenv fdtfile $tftproot/u-boot.dtb; setenv kernelfile $tftproot/uImage; setenv ramdiskfile $tftproot/rootfs.ext2.gz.uboot; setenv rootfile $tftproot/rootfs.jffs2'
echo == commands ==
setenv bootflash 'setenv bootargs root=/dev/mtdblock3 rw rootfstype=jffs2 console=ttyS0,$baudrate mtdparts=physmap-flash.0:0x80000(boot),0x80000(fdt),0x$kernsize(kernel),0x$rootsize(root); bootm $kernaddr - $fdtaddr'
setenv flashall 'run flashenv; run flashfdt; run flashkernel; run flashroot'
setenv flashenv 'run setargs; tftp $loadaddr $envfile; autoscr $loadaddr; saveenv'
setenv flashfdt 'run setargs; tftp $loadaddr $fdtfile; erase $fdtaddr +$filesize; cp.b $loadaddr $fdtaddr $filesize'
setenv flashkernel 'run setargs; tftp $loadaddr $kernelfile; erase $kernaddr +$kernsize; cp.b $loadaddr $kernaddr $filesize'
setenv flashroot 'run setargs; tftp $loadaddr $rootfile; erase $rootaddr +$rootsize; cp.b $loadaddr $rootaddr $filesize'
setenv flashuboot 'run setargs; tftp $loadaddr $ubootfile; protect off $ubootaddr +$filesize; erase $ubootaddr +$filesize; cp.b $loadaddr $ubootaddr $filesize'
echo == cleanup ==
setenv envfile
setenv ethact
setenv fileaddr
setenv filesize
setenv fdtfile
setenv kernelfile
setenv ramdiskfile
setenv rootfile
setenv ubootfile