DESCRIPTION = "GNU Octave is a high-level language, primarily intended for numerical computations. \
It provides a convenient command line interface for solving linear and nonlinear problems numerically, \
and for performing other numerical experiments using a language that is mostly compatible with Matlab. \
It may also be used as a batch-oriented language."
HOMEPAGE = "http://www.gnu.org/software/octave/"
SECTION = "console/scientific"
LICENSE = "GPL"
DEPENDS = "readline ncurses fftw"
RDEPENDS = "libfftw3"
# fftw compiled with --disable-fortran

SRC_URI = "ftp://ftp.octave.org/pub/octave/bleeding-edge/${PN}-${PV}.tar.gz \
           file://no_configure_test.patch;patch=1"

inherit autotools

EXTRA_OECONF = "--without-hdf5"

do_configure() {
	gnu-configize
	oe_runconf
}

PACKAGES =+ "libcruft liboctave liboctinterp octave-m"
PACKAGES =+ "libcruft-dev liboctave-dev liboctinterp-dev"
PACKAGES =+ "libcruft-dbg liboctave-dbg liboctinterp-dbg"

FILES_libcruft = "${libdir}/${PN}-${PV}/libcruft.so.*"
FILES_libcruft-dev = "${libdir}/${PN}-${PV}/libcruft.so"
FILES_libcruft-dbg = "${libdir}/${PN}-${PV}/.debug/libcruft*"

FILES_liboctave = "${libdir}/${PN}-${PV}/liboctave.so.*"
FILES_liboctave-dev = "${libdir}/${PN}-${PV}/liboctave.so"
FILES_liboctave-dbg = "${libdir}/${PN}-${PV}/.debug/liboctave*"

FILES_liboctinterp = "${libdir}/${PN}-${PV}/liboctinterp.so.*"
FILES_liboctinterp-dev = "${libdir}/${PN}-${PV}/liboctinterp.so"
FILES_liboctinterp-dbg = "${libdir}/${PN}-${PV}/.debug/liboctinterp*"

# octave-m provides matlab routines in .m file format
FILES_${PN}-m = "${datadir}/${PN}/*"

FILES_${PN}-dbg += "${libexecdir}/${PN}/${PV}/oct/${TARGET_SYS}/.debug"

do_stage() {
        autotools_stage_all
}