//===== eAthena Script =======================================
//= Thief Job Quest
//===== By: ==================================================
//= eAthena dev team
//===== Current Version: =====================================
//= 1.7
//===== Compatible With: =====================================
//= eAthena SVN
//===== Description: =========================================
//= [Aegis Conversion]
//= Job quest for Thief classes
//===== Additional Comments: =================================
//= Fully working
//= v1.1 Added instant job change for High Novice [Lupus]
//= 1.3 Added Baby Class support [Lupus]
//= v1.4 Optimised and moved first checker to Jfunc1-1 [massdriller]
//= Fixed possible EXP abuse [Lupus]
//= 1.5 Now saves/restores all quest skills [Lupus]
//= 1.6 Merged back JFunc [Lupus] 1.6a typos
//= 1.7 Rescripted to Aegis 10.3 stadards. [L0ne_W0lf]
//=	No longer uses function "F_ToHigh"
//============================================================

moc_prydb1,39,129,2	script	Thief Guide	69,{
	if (Upper == 1) {
		if (ADVJOB == Job_Assassin_Cross || ADVJOB == Job_Stalker) {
			if (Class == Job_Novice_High) {
				mes "[Thief Guide]";
				mes "Huh? te conozco? Me pareces algo familiar. No tienes un gemelo, verdad?";
				next;
				if (getskilllv(1) < 9) {
					mes "[Thief Guide]";
					mes "Qu, quieres ser un Thief? Lo siento, pero necesitas ms entrenamiento.";
					next;
					mes "[Thief Guide]";
					mes "Toma tu tiempo y aprende todas las Basic Skills. Bien, nos vemos!";
					close;
				}
				mes "[Thief Guide]";
				mes "Bien, tengo este sentimiento de que has pasado por toda una vida de lucha, asi que eres promovido a Thief en este momento. Que mejor que darles a los chicos duros lo que quieren...";
				next;
				skill 143,0,0;
				jobchange Job_Thief_High;
				skill 149,1,0;
				skill 150,1,0;
				skill 151,1,0;
				skill 152,1,0;
				mes "[Thief Guide]";
				mes "Ya que te has convertido en Thief, vive como un Thief. Ahora, ve por ello!";
				close;
			}
			else {
				mes "[Thief Guide]";
				if (sex)
					mes "Eh, tipo.";
				else
					mes "Eh, muchacho.";
				close;
			}
		}
		else {
			mes "[Thief Guide]";
			if (sex)
				mes "Eh, tipo.";
			else
				mes "Eh, muchacho.";
			mes "...Eh! Mira tambin los papanatas quieren ser Thief!! Ahora largate, estoy ocupado.Despus!";
			close;
		}
	}
	if (BaseJob == Job_Thief) {
		mes "[Thief Guide]";
		mes "Si tienes algun problema, no dudes en decirmelo inmediatamente,bien?";
		close;
	}
	else if (BaseJob != Job_Novice && BaseJob != Job_Thief) {
		mes "[Thief Guide]";
		mes "Qu demonios...?";
		switch(Class) {
		case 1:
			mes "Huh.";
			mes "Ahora, esa es";
			mes "una gran espada.";
			next;
			mes "[Thief Guide]";
			mes "...";
			mes "Tratando de";
			mes "compensar algo";
			mes "...compaero?";
			break;
		case 2:
			mes "Qu hace un mago aqu? No deberias estar haciendo trucos con las cartas en otra parte? Ah bien, esto es un pas libre...";
			next;
			mes "[Thief Guide]";
			mes "Oh espera,";
			mes "Esto no es...";
			mes "sal de aqui!";
			break;
		case 3:
			mes "Hombre, no deben los";
			mes "Arqueros estar jugando";
			mes "en el bosque";
			mes "o algo asi?";
			break;
		case 4:
			mes "T sabes que todos roban para vivir, no?. Qu haces en este lugar, Aclito?";
			break;
		case 5:
			mes "Eres un Mercante,no?";
			mes "Por qu ests";
			mes "caminando en una cueva";
			mes "de Ladrones?!";
			next;
			mes "[Thief Guide]";
			mes "Ests pidiendo";
			mes "que te roben!!";
			mes "Vamos, date prisa y";
			mes "sal de aqu";
			break;
		case 8:
			mes "Oh mi Dios...";
			mes "estoy muriendo?";
			next;
			mes "[Thief Guide]";
			mes "Porque para que otra cosa vendria un Priest hasta aqu?. Supongo que sera mejor empezar confesando todas mis fechorias";
			close;
		case 12:
			mes "No solias ser uno de nosotros?! Hombre, te has cambiado!. Pareces realmente peligroso ahora...";
			close;
		case 17:
			mes "Hombre, te hiciste realmente cool de un momento a otro! Debes tener algunas habilidades con las que slo puedo soar!";
			close;
		}
		next;
		mes "[Thief Guide]";
		mes "*Sigh* Mira, realmente no hay necesidad de que ests en este tipo de lugar. Deberias ir donde debes ir.";
		close;
	}
	if (job_thief_q == 3 && countitem(1069) > 0 || countitem(1070) > 0) {
		mes "[Thief Guide]";
		mes "Hmmm?";
		mes "Juntaste Mushrooms para";
		mes "la prueba de Thief, no?";
		next;
		mes "[Thief Guide]";
		mes "En ese caso, habla con el otro chico a mi lado. El es el responsable de contar los Mushrooms.";
		close;
	}
	else if (job_thief_q == 3) {
		mes "[Thief Guide]";
		mes "Como era la";
		mes "Granja de Mushroom?";
		mes "Tiene algo divertido?";
		next;
		if (select("Si, bastante.:Fue horrible.") == 1) {
			mes "[Thief Guide]";
			mes "Eh eh! Esa es una buena actitud. En nuestra linea de trabajo, debes disfrutar ensuciarte las manos de una manera u otra.";
			close;
		}
		mes "[Thief Guide]";
		mes "Si? He estado alli tambien, y creeme, se porque aquel lugar no es para ir a tomar el te. Despues de todo ser un Ladron no es todo glamour y vida nocturna.";
		close;
	}
	if (job_thief_q == 2) {
		mes "[Thief Guide]";
		mes "Hey, que haces aqui? No se supone que debes juntar Mushrooms? O necesito explicartelo de nuevo?";
		next;
		if  (select("Si.:No, estoy bien") == 1) {
			mes "[Thief Guide]";
			mes "*Sigh* Bien, siempre hay alguno en el grupo. Escucha con cuidado.";
			next;
			mes "[Thief Guide]";
			mes "Bien, para tu prueba, debes robar mushrooms de una granja. No te preocupes, el dueo de la granja merece ser robado.";
			next;
			mes "[Thief Guide]";
			mes "De todos modos, debes recolectar dos tipos de Mushrooms: ^0000FFOrange Net Mushrooms^000000 and ^0000FFOrange Gooey Mushrooms^000000.";
			next;
			mes "[Thief Guide]";
			mes "Ten cuidado, ya que hay monstruos en los alrededore que estan alli para proteger a los Mushrooms. Por lo tanto, este no sera un paseo por el parque.";
			next;
			mes "[Thief Guide]";
			mes "Cuando vuelvas de la recoleccion de Mushrooms, se clasificaran los Mushrooms recolectados.";
			next;
			mes "[Thief Guide]";
			mes "Por cada Orange Net Mushroom ganas 3 puntos, y tu obtienes 1 punto por casa Orange Gooey Mushroom. Necesitas un total de 25 puntos para pasar la prueba.";
			next;
			mes "[Thief Guide]";
			mes "Ve afuera y dirigete a la parte Este de las Piramides. Veras uno de mis compaero entre dos columnas.";
			next;
			mes "[Thief Guide]";
			mes "Habla con aquel chico, y te llevara a la granja por una puerta trasera.";
			next;
			mes "[Thief Guide]";
			mes "Sobre aquel campo, pienso que tus coordenadas seran '^FF0000141, 125^000000.' Simplemente escribe ^3355FF/where^000000 en la parte derecha de tu ventana de chat para ver tus actuales coordenadas.";
			close;
		}
		mes "[Thief Guide]";
		mes "Huh. Por un segundo, pense que tenias algo realmente importante que decir.";
		close;
	}
	mes "[Thief Guide]";
	if (job_thief_q == 0) {
		mes "Que te trae";
		mes "a este agujero de rata?";
	}
	else {
		mes "Ah...";
		mes "volviste.";
		mes "Estas seguro";
		mes "de intertarlo otra vez?";
	}
	next;
	if (select("!Hey, vine aqui para ser un Thief!:Nah, solo miro los alrededores") == 1) {
		if (job_thief_q == 0) {
			mes "[Thief Guide]";
			mes "Heh, Me gusta tu confianza. Sin embargo, tu sabes que un ladrn no es tan sucio hasta que lo es.";
			next;
			mes "[Thief Guide]";
			mes "Sin embargo...";
			mes "Realmente";
			mes "quieres ser";
			mes "un Thief?";
			next;
			switch(select("Si.:No, solo gasta su tiempo.:Por que se hizo ladron?")) {
			case 1:
				mes "[Thief Guide]";
				mes "Realmente...";
				break;
			case 2:
				mes "[Thief Guide]";
				mes "Yeah...";
				mes "Puedo ver eso";
				break;
			case 3:
				mes "[Thief Guide]";
				mes "Mm...?";
				mes "No tenia ninguna opcion entonces. Robar o pasar hambre. Pero no tengo porque darte la historia de mi vida.";
				break;
			}
			next;
			mes "[Thief Guide]";
			mes "Asi que deseas";
			mes "aplicarte para ser";
			mes "un Thief o no?";
			next;
			switch(select("Si, quiero.:Estoy muy asustado de ser un ladron")) {
			case 1:
				mes "[Thief Guide]";
				mes "Bien, dime";
				mes "tu nombre.";
				next;
				mes "[Thief Guide]";
				mes "" + strcharinfo(0) + "?";
				mes "Que clase de nombre es " + strcharinfo(0) + "? De todos modos, dame un segundo.";
				set job_thief_q,1;
				next;
				mes "[Thief Guide]";
				mes "Bien, tu registracion ha sido procesada. Puedes comenzar tu prueba, si estas listo.";
				next;
				switch(select("Yeah, Lo estoy.:No, No estoy preparado.")) {
				case 1:
					break;
				case 2:
					mes "[Thief Guide]";
					mes "No estas listo?";
					mes "Como no puedes";
					mes "estar preparado?!";
					close;
				}
				break;
			case 2:
				mes "[Thief Guide]";
				mes "!Demasiao miedo?!?";
				mes "Hahahahahahah!";
				mes "Oh, por favor...!";
				mes "Esto es alegre";
				close;
			}
		}
		else {
			mes "[Thief Guide]";
			mes "Bien...";
			mes "Dame";
			mes "un segundo.";
			next;
		}
		mes "[Thief Guide]";
		mes "Tu nombre es...";
		mes strcharinfo(0) + "? Um, donde esta?.Ah, aqui esta. Veamos...";
		next;
		mes "[Thief Guide]";
		if (getskilllv(1) < 9) {
			mes "No es lindo? Puedo ver que seas ambicioso, pero tienes que aprender todas las Basic Skill antes de que puedas hacerte un Thief.";
			close;
		}
		mes "Bien. Mir tu Registro de Crimen, y pareces tener una historia muy interesante. Podras tener lo que se necesita para ser un Thief.";
		next;
		mes "[Thief Guide]";
		mes "Porque me da la gana, ahora decreto que has aprobado esta entrevista.Buen trabajo!";
		set job_thief_q,2;
		next;
		mes "[Thief Guide]";
		mes "Ahora, tu capacidad real tendra que ser probada. Sabes algo acerca de la prueba?";
		next;
		switch(select("Si, lo se.:Disculpa, no lo se.")) {
		case 1:
			mes "[Thief Guide]";
			mes "Ah si? Bien, esto hace la cosas mas faciles.";
			break;
		case 2:
			mes "[Thief Guide]";
			mes "Bien, permiteme informarte entonces. Escucha atentamente. Esta prueba decide si eres digno de convertirte en un Thief.";
			next;
			mes "[Thief Guide]";
			mes "Iras a la Granja de Shibu. El es el peor mercante, en terminos de caracter, en Morroc.";
			next;
			mes "[Thief Guide]";
			mes "Bien, para tu prueba, debes robar Mushrooms de su granja. No te preocupes chico, que merece ser robado.";
			next;
			mes "[Thief Guide]";
			mes "En cualquier caso, necesitas reunir dos tipos de Mushrooms: ^0000FFOrange Net Mushrooms^000000 and ^0000FFOrange Gooey Mushrooms^000000.";
			next;
			mes "[Thief Guide]";
			mes "Ten cuidado, ya que hay monstruos en los alrededore que estan alli para proteger a los Mushrooms. Por lo tanto, este no sera un paseo por el parque.";
			next;
			mes "[Thief Guide]";
			mes "Cuando vuelvas de la recoleccion de Mushrooms, se clasificaran los Mushrooms recolectados.";
			next;
			mes "[Thief Guide]";
			mes "Por cada Orange Net Mushroom ganas 3 puntos, y gana 1 punto por cada Orange Gooey Mushroom. Necesitas un total de 25 puntos para pasar la prueba.";
			next;
			mes "[Thief Guide]";
			mes "Ve fuera y sigue adelante hacia el Este de las Pirmides. Entonces veras a uno de nuestros compaeros entre dos columnas.";
			next;
			mes "[Thief Guide]";
			mes "Hablale a aquel tipo, y te llevara a la granja por la puerta de atras.";
			next;
			mes "[Thief Guide]";
			mes "Sobre aquel campo, pienso que tus coordenadas seran '^FF0000141, 125^000000.' Simplemente escribe ^3355FF/where^000000 en la parte derecha de tu ventana de chat para ver tus actuales coordenadas.";
		}
		next;
		mes "[Thief Guide]";
		mes "No olvide de hacer los preparativos necesarios antes de ir dentro de la Granja de Mushrooms. Has movimientos tan rpidamente como puedas e intenta que no maten, bien?";
		close;
	}
	close;
}

moc_prydb1,42,133,2	script	Comrade	118,{
	if (BaseJob == Job_Thief) {
		mes "[Brad]";
		mes "No tenemos ningun acontecimiento especial aun. Vente en otra ocasion cuando haya noticias, bien?";
		close;
	}
	else if (BaseJob != Job_Novice && BaseJob != Job_Thief) {
		mes "[Comrade]";
		mes "Um...";
		mes "No te pareces";
		mes "a un Thief.";
		next;
		mes "[Comrade]";
		mes "Que demonios estas";
		mes "haciendo aqui de todos modos?";
		close;
	}
	if (job_thief_q == 0 || job_thief_q == 1) {
		mes "[Comrade]";
		mes "Que pasa? Si quieres ser un Thief, habla con la chica a mi lado.";
		close;
	}
	else if (job_thief_q == 2) {
		mes "[Comrade]";
		mes "Pasaste la entrevista?";
		mes "Entonces que esperas?";
		close;
	}
	else if (job_thief_q == 3) {
		mes "[Comrade]";
		mes "Ah, la guia me hablo sobre ti. Dejame comprobar tus mushrooms...";
		if (countitem(1069) == 0 && countitem(1070) == 0) {
			next;
			mes "[Comrade]";
			mes "Que demonios!";
			mes "No tienes ningun Mushrooms en absoluto! Vuelve y consiguelos. De otra manera, no pasaras la prueba y no te haras un Thief!";
			close;
		}
		next;
		set .@thief_item1,countitem(1069) * 3;
		set .@thief_item2,countitem(1070);
		set .@total_thief,.@thief_item1 + .@thief_item2;
		set .@money_thief,((.@thief_item1 * 5) + (.@thief_item2 * 2)) + 200;
		mes "[Comrade]";
		if (countitem(1069) != 0) {
			mes "Primero, dejame comprobar las Orange Net Mushrooms que conseguiste.";
			mes "Huh, " + countitem(1069) + " de ellos.";
		}
		if (countitem(1070) != 0)
			mes "Ahora comprobare tus Orange Gooey Mushrooms. Estas son " + countitem(1070) + " reunidas.";
		next;
		mes "[Comrade]";
		mes "Asi que el";
		mes "total alcanzado...";
		next;
		mes "[Comrade]";
		mes "Hmmm. " + .@total_thief + " grados, multiplicado por la velocidad de la Luz, dividido por la integral de Pi altura de veces mas el valor absoluto de politica...";
		next;
		mes "[Comrade]";
		mes "Bien!";
		mes "He captado";
		next;
		mes "[Comrade]";
		if (.@total_thief > 25) {
			mes "Tienes mas";
			mes "de 25 puntos!";
			mes "Pasaste!";
		}
		else if (.@total_thief == 25) {
			mes "Exactamente 25 puntos!";
			mes "Lo has logrado!";
		}
		else {
			mes "Definitivamente menos de los 25 puntos que necesitas para pasar.Ve hasta alla y recoge mas Mushrooms!";
			close;
		}
		next;
		mes "[Comrade]";
		mes strcharinfo(0) + "...";
		mes "Has pasado la prueba oficial de Thief. Ahora eres uno de nosotros.";
		if (countitem(1069) != 0) delitem 1069,countitem(1069); //Mushroom_Of_Thief_1
		if (countitem(1070) != 0) delitem 1070,countitem(1070); //Mushroom_Of_Thief_2
		callfunc "Job_Change",Job_Thief;
		callfunc "F_ClearJobVar";
		next;
		mes "[Comrade]";
		mes "Felicitaciones por convertirte en un Thief! Desde ahora, eres un honorable representante de la Guild de Thief.";
		next;
		mes "[Comrade]";
		mes "Si traes verguenza a nuestro Clan, te matare. Espero que traigas orgullo a nuestros compaeros.";
		next;
		mes "[Brad]";
		mes "*Ahem* Bienvenido a la Guild, camarada! Soy Brad, y soy responsable de recuersos humanos aqui.";
		next;
		mes "[Brad]";
		mes "Aqui tienes una pequea subvencion para un principiante como tu. Para que lo gastes en lo que quieras. Bien entonces, te vere en los alrededores.";
		set zeny,zeny+.@money_thief;
		close;
	}
}

moc_ruins,141,125,3	script	Mr. Irrelevant	83,{
	if (BaseJob == Job_Thief) {
		mes "[Mr. Irrelevant]";
		mes "Ah, Veo que ahora eres un Thief. Siempre supe que querias unirtenos.";
		next;
		mes "[Mr. Irrelevant]";
		mes "Robar una granja de Mushroom es demasiado facil para ti ahora. Deberias aumentar tus habilidades y dominar nuestro arte.";
		close;
	}
	else if (BaseJob != Job_Novice && BaseJob != Job_Thief) {
		mes "[Mr. Irrelevant]";
		switch(rand(4)) {
		case 1:
			mes "Yo podria tomar una buena bebida alcoholica.";
			close;
		case 2:
			mes "Dame tu dinero.";
			next;
			mes "[Mr. Irrelevant]";
			mes "Es broma, Dame el reloj.";
			close;
		case 3:
			mes "A QUIEN ESTAS LLAMANDO PSICOPATA?!?!";
			close;
		case 4:
			mes "No tengo nada que decirte.Te importaria dejarme solo?";
			close;
		default:
			mes "Hoy parece un buen dia para ir a las piramides y de caza, con algunos de mis amigos.";
			close;
		}
	}
	if (job_thief_q == 3) {
		mes "[Mr. Irrelevant]";
		mes "Hahahahaha~!";
		mes "No has";
		mes "pasado la prueba aun?";
		mes "Bien, te dejare entrar...";
		close2;
		switch(rand(5)) {
		case 1: warp "job_thief1",228,106; end;
		case 2: warp "job_thief1",38,50; end;
		case 3: warp "job_thief1",66,331; end;
		case 4: warp "job_thief1",196,331; end;
		default: warp "job_thief1",309,234; end;
		}
	}
	else if (job_thief_q == 2) {
		mes "[Mr. Irrelevant]";
		mes "Hmm...";
		mes "Has venido a efectuar la prueba, verdad?. Puedo notar en tus ojos que sabes algo.";
		next;
		mes "[Mr. Irrelevant]";
		mes "Tu nombre es " + strcharinfo(0) + "? Ah, estas en la lista. Bien yo te hare entrar en la Granja de Mushroom, pero no puedo garantizar tu seguridad...";
		close2;
		set job_thief_q,3;
		switch(rand(5)) {
		case 1: warp "job_thief1",228,106; end;
		case 2: warp "job_thief1",38,50; end;
		case 3: warp "job_thief1",66,331; end;
		case 4: warp "job_thief1",196,331; end;
		default: warp "job_thief1",309,234; end;
		}
	}
	else if (job_thief_q == 1) {
		mes "[Mr. Irrelevant]";
		mes "Hay un olor extrao que viene de...ti. Ahora, por que lo harias?";
		close;
	}
	mes "[Mr. Irrelevant]";
	mes "Hey Novato! Por que no te unes a las filas de la Thief Guild? Ustedes los novatos siempre son bienvenidos a unirse a nosotros y nuestra causa egoista.";
	next;
	mes "[Mr. Irrelevant]";
	mes "Tu puedes obtener mas informacion en la habitacion subterranea en la Piramide 1 BF.";
	close;
}

// Monsters
//============================================================
job_thief1,0,0,0,0	monster	Orange Mushroom	1182,180,0,0,0
job_thief1,0,0,0,0	monster	Fabre	1184,50,0,0,0
job_thief1,0,0,0,0	monster	Chonchon	1183,50,0,0,0
job_thief1,0,0,0,0	monster	Spore	1014,30,0,0,0

//============================================================
// mapflag
//============================================================
job_thief1	mapflag	nomemo
job_thief1	mapflag	noteleport
job_thief1	mapflag	nosave	SavePoint
job_thief1	mapflag	nopenalty
job_thief1	mapflag	nobranch