@echo off
SET TWOCHECK=EMPTY%2
SET THREECHECK=EMPTY%3
SET FOURCHECK=EMPTY%4

SET QUANTITYA=5
IF NOT %THREECHECK%==EMPTY SET QUANTITYA=%3
SET QUANTITYB=%4
IF %FOURCHECK%==EMPTY SET QUANTITYB=%QUANTITYA%

IF %TWOCHECK%==EMPTY goto help
IF %1==-h goto help
IF %1==--help goto help
IF %1==/h goto help
IF %1==/? goto help
IF %1==help goto help

GOTO doit

:help
echo makesagebomb 1.1.0
echo Usage:
echo         makesagebomb filename subdirectory quantity [quantityb]
echo.
echo         -filename:     The filename to use as the source image
echo         -subdirectory: The subdirectory to place resized files in
echo         -quantity:     Maximum number of horizontal pixels to remove
echo         -quantityb:    Maximum number of vertical pixels to remove
echo.
echo If quantityb is not present, quantity's value will be used.
echo quantity x quantityb "duplicate" images will be produced.

goto end

:doit

IF NOT EXIST .\%2\NUL mkdir %2


SET OUTMAX=%QUANTITYA%
SET INMAX=%QUANTITYB%

SET OUTCOUNTER=0
:startouterloop
IF %OUTCOUNTER%==%OUTMAX% GOTO endouterloop

SET INCOUNTER=0
:startinnerloop
IF %INCOUNTER%==%INMAX% GOTO endinnerloop

FOR %%G IN (%1) DO imagemagick %%G -shave %OUTCOUNTER%x%INCOUNTER% %2\%OUTCOUNTER%x%INCOUNTER%%%G

SET /A INCOUNTER=%INCOUNTER%+1
goto startinnerloop
:endinnerloop

SET /A OUTCOUNTER=%OUTCOUNTER%+1
goto startouterloop

:endouterloop

:end